RealArea69 v0.6.2

    Compartilhe

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    RealArea69 v0.6.2

    Mensagem por RafaQN em Sab 02 Jan 2016, 23:24

    RealArea69

    Autor geral: Deadstroke (meu atual perfil)

    Link do mod showroom: http://brmodstudio.forumeiros.com/t5147-real-area-69


    Última edição por RafaQN em Ter 16 Fev 2016, 14:31, editado 18 vez(es)

    Junior_Djjr
    Scripter CLEO - Avançado
    Scripter CLEO - Avançado

    Título : Junior, o periquito.
    Plataforma : PC
    Mensagens : 19529
    Reputação : 539
    Idade : 21
    Localização : Ibitinga - SP
    Link : www.MixMods.com.br

    Re: RealArea69 v0.6.2

    Mensagem por Junior_Djjr em Sab 02 Jan 2016, 23:56

    Eita troço grande
    Esses "script base" q vc citou, vc copiou partes inteiras? Oq exatamente vc usou como base?




    Código:
    not $Active_Interior == 1
    Soh não ativar caso estiver no interior 1? E quanto aos outros 8/9 (acho) interiores? O script soh não ativará se por exemplo vc estiver dentro da casa do CJ, ou mansão do Madd Dogg etc, continuará ativando em safe houses, estádios etc


    Código:
    Model.Load(2887) //marcar para carregar
    Model.Load(2888)
    Model.Load(2889)
    038B: load_requested_models //carregar
    if and
       Model.Available(2887) //checar se carregou? mas jah carregou
       Model.Available(2888)
       Model.Available(2889)
    jf @SEARCHLIGHTS01 //se não carregou, voltar para o início do código (onde irá carregar de novo)
    Não eh nesse caso, jah q vc jah forçou o carregamento, mas se vc não tivesse forçado o carregamento o script iria voltar pra trás e carregar DE NOVO! Se por exemplo os modelos demorassem 1 segundo para carregar e seu GTA esteja a 60 FPS, iria marcar o modelo pra ser carregado 60 vezes! Se ainda não carregou não quer dizer q vc tem q carregar de novo

    Soh eh necessário 1 player.defined no topo do script
    Até o main.scm usa outros, realmente não sei pq, mas nunca vi necessidade alguma em usar mais. Se o player jah está definido, ele continuará definido o tempo q for, ele nunca deixará de ser definido durante o gameplay, nem q vc morra ou seja preso, continuará lah o player criado sempre


    O script em si está bom msm, mas aparentemente vc aprendeu as coisas sozinho pois fez erros q bastasse ler o tutorial de cleo do fórum q não cometeria, além deq vc programa em low level (labels, jumps...) então eh pq vc viu scripts descompilados e quis fazer igual
    Recomendo ler
    http://brmodstudio.forumeiros.com/t203-indice-de-tutoriais-cleo-script-scm

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Dom 03 Jan 2016, 00:18

    Scripts de base que usei:
    - Para o R69-enters, peguei os trechos de entradas do EHI e alterei colocando alguns critérios de entrada (por exemplo: os portões da área só se abrirão se for "policial" (SPOILER!)) e o disable air defense system com uma marca para ser ativado;
    - Para os R69-searchlights e R69-searchlights-2 usei uma parte dos scripts do 'Searchlights in Area 69' para fazer os holofotes luminosos;
    - As outras coisas acredito que tenham vindo de inspiração minha e de missões do GTA.

    Vou corrigir sobre o carregamento de modelos e sobre entrar em interiores (preciso ver como funciona direito) na próxima versão.

    E sobre o player.defined, acho que em algumas partes do script , se o player morrer, ser preso etc. precisaria desativar o mod. Ou não?

    E estou lendo os tutoriais, apenas não passei os scripts para high level por serem grandes mesmo hahaha. Vê no post do 'health & armour' que fiz desse jeito.

    Espero corrigir esses erros em breve. E obrigado por responder rápido...

    Junior_Djjr
    Scripter CLEO - Avançado
    Scripter CLEO - Avançado

    Título : Junior, o periquito.
    Plataforma : PC
    Mensagens : 19529
    Reputação : 539
    Idade : 21
    Localização : Ibitinga - SP
    Link : www.MixMods.com.br

    Re: RealArea69 v0.6.2

    Mensagem por Junior_Djjr em Dom 03 Jan 2016, 00:45

    @RafaQN escreveu:E sobre o player.defined, acho que em algumas partes do script , se o player morrer, ser preso etc. precisaria desativar o mod. Ou não?
    Como eu disse, eu nunca vi o player deixar de ser definido em nenhum momento
    @Junior_Djjr escreveu:Soh eh necessário 1 player.defined no topo do script
    Até o main.scm usa outros, realmente não sei pq, mas nunca vi necessidade alguma em usar mais. Se o player jah está definido, ele continuará definido o tempo q for, ele nunca deixará de ser definido durante o gameplay, nem q vc morra ou seja preso, continuará lah o player criado sempre
    Simplesmente cheque se está Wasted ou Busted

    E simplesmente cheque se não está no interior 0, o interior 0 eh o exterior, se ele não está no 0 quer dizer q ele está em algum interior
    E não tenho certeza, mas tenho a impressão deq $Active_Interior não funciona automaticamente no GTA sem mods, e sim algum mod q atualiza ela, não sei, eh sempre bom usar o opcode de pegar o active interior e botar numa var local msm, assim tbm será compatível com mods de outros main.scm

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Dom 03 Jan 2016, 22:04

    RealArea69 v0.2
    - Script reescrito com o source em high level com pequenas correções;
    - Melhorado o sistema de detecção de holofotes destruídos;
    - Melhorado a abertura do portão pneumático;
    - Possibilidade de ativar ou desativar os o sistema de defesa aérea (antes só desativava);
    - Textos foram inseridos de aviso para ativar entradas e sistemas;
    - Vem com um arquivo para o gta3.img que era necessário para os portões de entrada e de acesso à garagem ativarem (se tiver o EHI ele não é necessário);
    - Eliminado o bug de caso atirar em todos os holofotes à noite, eles voltam ao normal do nada.

    SCRIPTS CLEO:

    - R69-enters.cs -> coloca sistemas de entradas para a área 69 e sistemas de detecção primários nela;
    - R69-searchlights.cs e R69-searchlights-2.cs -> coloca searchlights no local, tanto na área principal quanto na área de veículos (os scripts são praticamente iguais, só mudam as coordenadas de cada um).

    R69-enters.cs
    Código:
    {$CLEO .cs}
    0000: NOP
    thread 'R69-Ent'

    while true    
        wait 0
        077E: get_active_interior_to 7@
        //Verificar personagem e se não está em interior
        if and
        0039:   7@ == 0
        Player.Defined($PLAYER_CHAR)
        then
            //Verificar se o personagem está na região da área 69
            if or
            00EC:   actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0  
            0154:   actor $PLAYER_ACTOR in_zone 'REST'
            then
                
                //Colocar e ativar portões da área 69
                1@ = Object.Create(985, 139.075, 1941.32, 18.335)
                Object.Angle(1@) = 0.0
                2@ = Object.Create(986, 131.115, 1941.32, 18.335)
                Object.Angle(2@) = 0.0
                3@ = Object.Create(985, 285.641, 1817.41, 16.651)
                Object.Angle(3@) = 270.0
                4@ = Object.Create(986, 285.641, 1825.37, 16.651)
                Object.Angle(4@) = 270.0
                0006: 5@ = 1
                0006: 32@ = 30000
                0A24: enable_military_zones_wanted_level 0
                07A8: enable_area69_sam 1
                
                //Scripts das entradas da área 69
                while true
                    wait 0
                    
                    //Primeiros parâmetros
                    077E: get_active_interior_to 7@
                    0AAA: 0@ = thread 'MAF4' pointer
                    
                    //primeiro portão
                    if and
                    03CA:   object 1@ exists
                    03CA:   object 2@ exists
                    then
                        //Verificar se está no ponto e não é procurado
                        if and
                        00EC:   actor $PLAYER_ACTOR sphere 0 near_point 135.095 1941.32 radius 8.0 15.0
                        810F:   not player $PLAYER_CHAR wanted_level > 2
                        then
                            //Verificar se é um "policial"
                            if or
                                0500:   player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                                056C:   actor $PLAYER_ACTOR driving_police_car
                                00DD:   actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                            then
                                //Abrir portões
                                034E: move_object 1@ to 145.475 1941.32 18.335 speed 0.1 0.0 0.0 collision_check 0
                                034E: move_object 2@ to 124.715 1941.32 18.335 speed 0.1 0.0 0.0 collision_check 0
                            else
                                //Fechar portões
                                034E: move_object 1@ to 139.075 1941.32 18.335 speed 0.1 0.0 0.0 collision_check 0
                                034E: move_object 2@ to 131.115 1941.32 18.335 speed 0.1 0.0 0.0 collision_check 0
                            end
                        else
                            //Fechar portões
                            034E: move_object 1@ to 139.075 1941.32 18.335 speed 0.1 0.0 0.0 collision_check 0
                            034E: move_object 2@ to 131.115 1941.32 18.335 speed 0.1 0.0 0.0 collision_check 0
                        end
                    else
                        Object.Destroy(1@)
                        Object.Destroy(2@)
                        Object.Destroy(3@)
                        Object.Destroy(4@)
                        0A24: enable_military_zones_wanted_level 0
                        07A8: enable_area69_sam 1
                        break
                    end
              
                    //segundo portão
                    if and
                    03CA:   object 3@ exists
                    03CA:   object 4@ exists
                    then
                        //Verificar se está no ponto e não é procurado
                        if and
                        00EC:   actor $PLAYER_ACTOR sphere 0 near_point 285.641 1821.39 radius 15.0 8.0
                        810F:   not player $PLAYER_CHAR wanted_level > 2
                        then
                            //Verificar se é um "policial"
                            if or
                                0500:   player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                                056C:   actor $PLAYER_ACTOR driving_police_car
                                00DD:   actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                            then
                                //Abrir portões
                                034E: move_object 3@ to 285.641 1811.81 16.651 speed 0.0 0.1 0.0 collision_check 0
                                034E: move_object 4@ to 285.641 1830.97 16.651 speed 0.0 0.1 0.0 collision_check 0
                            else
                                //Fechar portões
                                034E: move_object 3@ to 285.641 1817.41 16.651 speed 0.0 0.1 0.0 collision_check 0
                                034E: move_object 4@ to 285.641 1825.37 16.651 speed 0.0 0.1 0.0 collision_check 0
                            end
                        else
                            //Fechar portões
                            034E: move_object 3@ to 285.641 1817.41 16.651 speed 0.0 0.1 0.0 collision_check 0
                            034E: move_object 4@ to 285.641 1825.37 16.651 speed 0.0 0.1 0.0 collision_check 0
                        end
                    else
                        Object.Destroy(1@)
                        Object.Destroy(2@)
                        Object.Destroy(3@)
                        Object.Destroy(4@)
                        0A24: enable_military_zones_wanted_level 0
                        07A8: enable_area69_sam 1
                        break
                    end
                
                    // Área de saída do jetpack
                    if and
                    not 0@ > 0
                    03CA:   object $2670 exists
                    00EC:   actor $PLAYER_ACTOR sphere 0 near_point 269.081 1884.109 radius 8.0 8.0
                    0A0C:   player $PLAYER_CHAR on_jetpack
                    then
                        034E: move_object $2670 to 276.14 1884.06 15.924 speed 0.05 0.0 0.0 collision_check 0
                    else
                        034E: move_object $2670 to 268.664 1884.06 15.925 speed 0.05 0.0 0.0 collision_check 0
                    end
                
                    //Entrada de ventilação
                    if and
                    not 0@ > 0
                    03CA:   object $Object_M_A51_VENTCOVERB exists
                    then
                        Object.Destroy($Object_M_A51_VENTCOVERB)
                    end
                
                    //Desabilitação do sistema de defesa aérea
                    if and
                    not 0@ > 0
                    0039:   5@ == 1                
                    then
                        //Verificação: posição do player para apertar botões para DESATIVAÇÃO
                        if
                            0102:   actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                        then
                            0ACC: "Press 'enter/exit vehicle' to DISABLE the air defense system." time 100
                            if and
                            0102:   actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                            00E1:   player 0 pressed_key 15
                            then
                                gosub @ACTIVE
                                //Desativando defesa aérea da área 69
                                0ACD: "Air defense system disabled." time 4000
                                07A8: enable_area69_sam 0
                                0006: 5@ = 0
                                wait 4000
                            end
                        end                    
                    else
                        //Verificação: posição do player para apertar botões para DESATIVAÇÃO
                        if
                            0102:   actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                        then
                            0ACC: "Press 'enter/exit vehicle' to ENABLE the air defense system." time 100
                            if and
                            0102:   actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                            00E1:   player 0 pressed_key 15
                            then
                                gosub @ACTIVE
                                //Ativando defesa aérea da área 69
                                0ACD: "Air defense system enabled." time 4000
                                07A8: enable_area69_sam 1
                                0006: 5@ = 1
                                wait 4000
                            end
                        end                    
                    end
                
                    //Portão pneumático
                    if and
                    03CA:   object $Object_M_A51_BLASTDOORL exists
                    03CA:   object $Object_M_A51_BLASTDOORR exists
                    not 0@ > 0
                    then
                        if
                        8029:  not 32@ >= 30000
                        then
                            //Abrindo os blastdoors
                            034E: move_object $Object_M_A51_BLASTDOORR to 219.941 1874.571 13.903 speed 0.1 0.0 0.0 collision_check 0
                            034E: move_object $Object_M_A51_BLASTDOORL to 207.842 1874.571 13.903 speed 0.1 0.0 0.0 collision_check 0
                        else                            
                            //Ativação dos blastdoors por dentro
                            if
                            0102:   actor $PLAYER_ACTOR in_sphere 246.9874 1860.8265 14.084 radius 2.0 2.0 5.0 sphere 1 stopped_on_foot
                            then
                                0ACC: "Press 'enter/exit vehicle' to open the blastdoors." time 100
                                if and
                                0102:   actor $PLAYER_ACTOR in_sphere 246.9874 1860.8265 14.084 radius 2.0 2.0 5.0 sphere 1 stopped_on_foot
                                00E1:   player 0 pressed_key 15
                                then
                                    gosub @ACTIVE
                                    //Abrindo os blastdoors
                                    034E: move_object $Object_M_A51_BLASTDOORR to 219.941 1874.571 13.903 speed 0.1 0.0 0.0 collision_check 0
                                    034E: move_object $Object_M_A51_BLASTDOORL to 207.842 1874.571 13.903 speed 0.1 0.0 0.0 collision_check 0
                                    0ACD: "The blastdoors is opening. You have few time to go out." time 4000
                                    0006: 32@ = 0
                                    wait 4000
                                else
                                    //Fechando os blastdoors
                                    034E: move_object $Object_M_A51_BLASTDOORL to 211.842 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                    034E: move_object $Object_M_A51_BLASTDOORR to 215.941 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                end
                            else
                                //Ativação dos blastdoors por fora, se não estiver sendo procurado
                                if
                                not Player.WantedLevel($PLAYER_CHAR) > 2
                                then
                                    if
                                        0102:   actor $PLAYER_ACTOR in_sphere 211.4867 1812.2637 21.8594 radius 2.0 2.0 5.0 sphere 1 stopped_on_foot
                                    then
                                        0ACC: "Press 'enter/exit vehicle' to open the blastdoors." time 100
                                        if and
                                        0102:   actor $PLAYER_ACTOR in_sphere 211.4867 1812.2637 21.8594 radius 2.0 2.0 5.0 sphere 1 stopped_on_foot
                                        00E1:   player 0 pressed_key 15
                                        then
                                            gosub @ACTIVE
                                            //Abrindo os blastdoors
                                            034E: move_object $Object_M_A51_BLASTDOORR to 219.941 1874.571 13.903 speed 0.1 0.0 0.0 collision_check 0
                                            034E: move_object $Object_M_A51_BLASTDOORL to 207.842 1874.571 13.903 speed 0.1 0.0 0.0 collision_check 0
                                            0006: 32@ = 0
                                            0ACD: "The blastdoors is opening. You have few time to go in." time 4000
                                            wait 4000
                                        else
                                            //Fechando os blastdoors
                                            034E: move_object $Object_M_A51_BLASTDOORL to 211.842 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                            034E: move_object $Object_M_A51_BLASTDOORR to 215.941 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                        end
                                    else
                                        //Fechando os blastdoors
                                        034E: move_object $Object_M_A51_BLASTDOORL to 211.842 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                        034E: move_object $Object_M_A51_BLASTDOORR to 215.941 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                    end
                                else
                                    //Fechando os blastdoors
                                    034E: move_object $Object_M_A51_BLASTDOORL to 211.842 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                    034E: move_object $Object_M_A51_BLASTDOORR to 215.941 1874.571 13.903 speed 0.05 0.0 0.0 collision_check 0
                                end      
                            end    
                        end
                    end
                    
                    //Invasão noturna!!!
                    if
                        not 0@ > 0
                    then
                        //Parâmetros do dia
                        00BF: 9@ = current_time_hours, 8@ = current_time_minutes
                        if and
                        9@ >= 5
                        21 > 9@                
                        //Caso seja dia
                        then
                            if or
                            0500:   player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                            056C:   actor $PLAYER_ACTOR driving_police_car
                            00DD:   actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                            //Não disfarçado
                            then
                                if
                                not Player.WantedLevel($PLAYER_CHAR) > 2
                                then
                                    //Não Procurado
                                    0A24: enable_military_zones_wanted_level 1    
                                else
                                    //Procurado
                                    0A24: enable_military_zones_wanted_level 0
                                end
                            else
                                //Caso estiver de dia e o player não estiver disfarçado
                                0A24: enable_military_zones_wanted_level 0
                            end                
                        //Caso seja noite
                        else
                            if and
                            8500:   not player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                            856C:   not actor $PLAYER_ACTOR driving_police_car
                            80DD:   not actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                            //Não disfarçado
                            then
                                if and
                                80DF:   not actor $PLAYER_ACTOR driving
                                8A0C:   not player $PLAYER_CHAR on_jetpack
                                not Player.WantedLevel($PLAYER_CHAR) > 2
                                //Se não estiver sendo procurado e não estiver num veículo
                                then
                                    0A24: enable_military_zones_wanted_level 1
                                //Se estiver sendo procurado ou estiver num veículo
                                else
                                    0A24: enable_military_zones_wanted_level 0
                                end
                            //Disfarçado
                            else
                                //Verificando se está procurado ou não
                                if
                                not Player.WantedLevel($PLAYER_CHAR) > 2
                                then
                                    0A24: enable_military_zones_wanted_level 1
                                else
                                    0A24: enable_military_zones_wanted_level 0                    
                                end
                            end  
                        end
                    end
                    
                    //Não invada a área 69 se estiver sendo procurado!!!
                    :SEARCHLIGHTS14
                    if and
                        0154:   actor $PLAYER_ACTOR in_zone 'REST'  // Restricted Area
                        Player.WantedLevel($PLAYER_CHAR) > 2
                        not 0@ > 0    
                    then
                    Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                    end
                  
                    
                    //Verificação final
                    //Verificar personagem está ativo e não está em um interior
                    if and
                    0039:   7@ == 0
                    8118:   not actor $PLAYER_ACTOR dead
                    8741:   not actor $PLAYER_ACTOR busted
                    then
                        //Verificar personagem e está na região da área 69
                        if or
                        00EC:   actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0  
                        0154:   actor $PLAYER_ACTOR in_zone 'REST'
                        then
                            continue
                        else
                            Object.Destroy(1@)
                            Object.Destroy(2@)
                            Object.Destroy(3@)
                            Object.Destroy(4@)
                            0A24: enable_military_zones_wanted_level 0
                            07A8: enable_area69_sam 1
                            break    
                        end
                    else
                        Object.Destroy(1@)
                        Object.Destroy(2@)
                        Object.Destroy(3@)
                        Object.Destroy(4@)
                        0A24: enable_military_zones_wanted_level 0
                        07A8: enable_area69_sam 1
                        break
                    end  
                //Fim dos scripts de entrada -> começa tudo de novo
                end                        
            //Caso não esteja na região, reiniciar
            end
        //Caso não seja definido ou estiver em interior, reiniciar
        end
    end

    :ACTIVE
    //ativando animação
    04ED: load_animation "CASINO"
    repeat
        wait 0
    until 04EE:   animation "CASINO" loaded                
    //Fazendo a animação
    0615: define_AS_pack_begin 8@
    0605: actor -1 perform_animation "SLOT_BET_02" IFP "CASINO" framedelta 4.0 loop 0 lockX 0 lockY 0 lockF 0 time -1
    0616: define_AS_pack_end 8@
    0618: assign_actor $PLAYER_ACTOR to_AS_pack 8@
    061B: remove_references_to_AS_pack 8@
    04EF: release_animation "CASINO"
    return

    R69-searchlights.cs
    Código:
    {$CLEO .cs}
    0000: NOP
    thread 'R69-1se'

    while true
    wait 0
        //Parâmetros iniciais
        0AAA: 0@ = thread 'MAF4' pointer    //Missão black project
        077E: get_active_interior_to 1@     //Valor de interior
        if and
        Player.Defined($PLAYER_CHAR)
        not 0@ > 0  //Não estar na missão black project
        0039:   1@ == 0 //Não estar em interior
        then
            if or
            00EC:   actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0  
            0154:   actor $PLAYER_ACTOR in_zone 'REST'
            then
                Model.Load(2887)
                Model.Load(2888)
                Model.Load(2889)
                038B: load_requested_models
                //Holofote 1
                3@ = Object.Init(2887, 161.962, 1933.043, 36.246)
                4@ = Object.Init(2888, 161.962, 1933.043, 36.246)
                5@ = Object.Init(2889, 161.962, 1933.043, 36.246)
                //Holofote 2
                8@ = Object.Init(2887, 233.486, 1934.789, 36.246)
                9@ = Object.Init(2888, 233.486, 1934.789, 36.246)
                10@ = Object.Init(2889, 233.486, 1934.789, 36.246)
                //Holofote 3
                13@ = Object.Init(2887, 267.116, 1895.241, 36.246)
                14@ = Object.Init(2888, 267.116, 1895.241, 36.246)
                15@ = Object.Init(2889, 267.116, 1895.241, 36.246)
                //Holofote 4
                18@ = Object.Init(2887, 262.145, 1807.62, 36.246)
                19@ = Object.Init(2888, 262.145, 1807.62, 36.246)
                20@ = Object.Init(2889, 262.145, 1807.62, 36.246)
                //Holofote 5
                23@ = Object.Init(2887, 166.003, 1849.937, 36.246)
                24@ = Object.Init(2888, 166.003, 1849.937, 36.246)
                25@ = Object.Init(2889, 166.003, 1849.937, 36.246)
                //Holofote 6
                28@ = Object.Init(2887, 113.439, 1814.405, 36.246)
                29@ = Object.Init(2888, 113.439, 1814.405, 36.246)
                30@ = Object.Init(2889, 113.439, 1814.405, 36.246)
                //Destruir modelos
                Model.Destroy(2887)
                Model.Destroy(2888)
                Model.Destroy(2889)
                gosub @SEARCHLIGHTS  
                
                while true
                wait 0
                
                    //Verificando atividade do mod
                    0AAA: 0@ = thread 'MAF4' pointer    //Missão black project
                    077E: get_active_interior_to 1@     //Valor de interior
                    if and
                    8118:   not actor $PLAYER_ACTOR dead
                    8741:   not actor $PLAYER_ACTOR busted
                    not 0@ > 0  //Não estar na missão black project
                    0039:   1@ == 0 //Não estar em interior
                    then
                        if and
                        80EC:   not actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0  
                        8154:   not actor $PLAYER_ACTOR in_zone 'REST'
                        then
                            for 1@ = 0 to 25 step 5
                                Object.Destroy(3@(1@,1i))
                                Object.Destroy(4@(1@,1i))
                                Object.Destroy(5@(1@,1i))
                                if
                                    06B3:   searchlight 2@(1@,1i) active
                                then
                                    06B2: destroy_searchlight 2@(1@,1i)
                                end    
                            end
                            break
                        end
                    else
                        wait 5000
                        for 1@ = 0 to 25 step 5
                            Object.Destroy(3@(1@,1i))
                            Object.Destroy(4@(1@,1i))
                            Object.Destroy(5@(1@,1i))
                            if
                                06B3:   searchlight 2@(1@,1i) active
                            then
                                06B2: destroy_searchlight 2@(1@,1i)
                            end    
                        end
                        break
                    end
                    
                    //Parâmetros do dia
                    00BF: 0@ = current_time_hours, 1@ = current_time_minutes
                    if and
                    0@ >= 5
                    21 > 0@                
                    
                    //Caso seja dia
                    then
                    
                        for 1@ = 0 to 25 step 5
                            if
                                06B3:   searchlight 2@(1@,1i) active
                            then
                                06B2:   destroy_searchlight 2@(1@,1i)
                            end
                        end
                    
                    //Caso seja noite    
                    else
                      
                        //Verificar se os holofotes estão corretamente ativos
                        for 1@ = 0 to 25 step 5
                            if and
                            86B3:   not searchlight 2@(1@,1i) active
                            0039:   6@(1@,1i) == 0
                            then
                                gosub @SEARCHLIGHTS
                            else
                                if and
                                06B3:   searchlight 2@(1@,1i) active
                                0039:   6@(1@,1i) == 1
                                then
                                    gosub @SEARCHLIGHTS
                                end
                            end
                        end
                        
                        //Sistema de detecção dos holofotes
                        if and
                        8500:   not player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                        856C:   not actor $PLAYER_ACTOR driving_police_car
                        80DD:   not actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                        810F:   not player $PLAYER_CHAR wanted_level > 2
                        then
                            for 1@ = 0 to 25 step 5
                                if and
                                03CA:   object 3@(1@,1i) exists
                                06B3:   searchlight 2@(1@,1i) active
                                06B7:   searchlight 2@(1@,1i) spotted_actor $PLAYER_ACTOR
                                then
                                    wait 500
                                    Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                                    break
                                end
                            end
                        end
                          
                        //Detecção de holoftes destruidos
                        //Verificando e destruindo holofotes
                        for 1@ = 0 to 25 step 5
                            071E: get_object 3@(1@,1i) health_to 0@
                            if and
                                5000 > 0@
                                8039:   not 6@(1@,1i) == 1
                            then
                                06B2: destroy_searchlight 2@(1@,1i)
                                066D: 0@ = attach_particle "SHOOTLIGHT" to_object 3@(1@,1i) with_offset 0.0 1.181 0.768 type 1
                                0006: 6@(1@,1i) = 1
                            end
                        end
                        //Se mais de um holofotes estiverem apagados
                        0@ = 0
                        for 1@ = 0 to 25 step 5
                            005A: 0@ += 6@(1@,1i)
                        end
                        if and
                        810F:   not player $PLAYER_CHAR wanted_level > 2
                        0029:   0@ >= 2
                        then
                            Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                        end
                        
                    end                
                end            
            end
        end  
    end

    :SEARCHLIGHTS
    //Luzes 1
    06B1: 2@ = create_searchlight_at 233.067 1934.892 33.139 radius 0.5 target 180.018 1904.214 17.255 radius 10.5
    06B4: set_searchlight 2@ path_between 180.018 1904.214 17.255 and 243.707 1903.543 18.639 speed 0.5
    //Luzes 2
    06B1: 7@ = create_searchlight_at 266.713 1894.979 34.139 radius 0.5 target 239.0798 1904.087 16.899 radius 10.5  
    06B4: set_searchlight 7@ path_between 239.0798 1904.087 16.899 and 188.371 1905.376 16.825 speed 0.5
    //Luzes 3
    06B1: 12@ = create_searchlight_at 261.97 1808.07 34.05 radius 0.5 target 166.119 1857.384 16.764 radius 10.5  
    06B4: set_searchlight 12@ path_between 166.119 1857.384 16.764 and 276.669 1856.339 16.671 speed 0.5
    //Luzes 4
    06B1: 17@ = create_searchlight_at 164.228 1837.892 34.05 radius 0.5 target 191.28 1822.46 16.83 radius 10.5
    06B4: set_searchlight 17@ path_between 191.28 1822.46 16.83 and 252.37 1821.89 17.04 speed 0.5
    //Luzes 5
    06B1: 22@ = create_searchlight_at 103.887 1901.057 35.723 radius 0.5 target 138.07 1823.01 16.88 radius 10.5
    06B4: set_searchlight 22@ path_between 138.07 1823.01 16.88 and 105.1 1867.21 16.97 speed 0.5
    //Luzes 6
    06B1: 27@ = create_searchlight_at 261.97 1808.07 36.05 radius 0.5 target 192.90 1809.56 16.80 radius 10.5
    06B4: set_searchlight 27@ path_between 192.90 1809.56 16.80 and 144.20 1812.52 16.78 speed 0.5
                        
    //Outras considerações gerais das luzes
    for 1@ = 0 to 25 step 5
        06CA: attach_searchlight 2@(1@,1i) to_tower 5@(1@,1i) to_housing 4@(1@,1i) to_bulb 3@(1@,1i) with_offset 0.0 1.181 0.768
        0A02: set_searchlight 2@(1@,1i) lights_through_obstacles 0
        071F: set_object 3@(1@,1i) health_to 5000
        0875: set_object 3@(1@,1i) immune_to_nonplayer 1
        0006: 6@(1@,1i) = 0
    end
    return

    R69-searchlights-2.cs
    Código:
    {$CLEO .cs}
    0000: NOP
    thread 'R69-2se'

    while true
    wait 0
        //Parâmetros iniciais
        0AAA: 0@ = thread 'MAF4' pointer    //Missão black project
        077E: get_active_interior_to 1@     //Valor de interior
        if and
        Player.Defined($PLAYER_CHAR)
        not 0@ > 0  //Não estar na missão black project
        0039:   1@ == 0 //Não estar em interior
        then
            if or
            00EC:   actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0  
            0154:   actor $PLAYER_ACTOR in_zone 'REST'
            then
                Model.Load(2887)
                Model.Load(2888)
                Model.Load(2889)
                038B: load_requested_models
                //Holofote 7 - da parte dos prédios
                3@ = Object.Init(2887, 103.946, 1901.047, 36.246)
                4@ = Object.Init(2888, 103.946, 1901.047, 36.246)
                5@ = Object.Init(2889, 103.946, 1901.047, 36.246)
                //Holofote 8
                8@ = Object.Init(2887, 344.0, 1805.0, 36.65)
                9@ = Object.Init(2888, 344.0, 1805.0, 36.65)
                10@ = Object.Init(2889, 344.0, 1805.0, 36.65)
                //Holofote 9
                13@ = Object.Init(2887, 203.31, 1958.96, 36.35)
                14@ = Object.Init(2888, 203.31, 1958.96, 36.35)
                15@ = Object.Init(2889, 203.31, 1958.96, 36.35)
                //Holofote 10
                18@ = Object.Init(2887, 375.529, 2070.224, 36.35)
                19@ = Object.Init(2888, 375.529, 2070.224, 36.35)
                20@ = Object.Init(2889, 375.529, 2070.224, 36.35)
                //Holofote 11
                23@ = Object.Init(2887, 374.858, 1903.950, 36.35)
                24@ = Object.Init(2888, 374.858, 1903.950, 36.35)
                25@ = Object.Init(2889, 374.858, 1903.950, 36.35)
                //Holofote 12
                28@ = Object.Init(2887, 377.23, 1978.96, 36.35)
                29@ = Object.Init(2888, 377.23, 1978.96, 36.35)
                30@ = Object.Init(2889, 377.23, 1978.96, 36.35)
                //Destruir modelos
                Model.Destroy(2887)
                Model.Destroy(2888)
                Model.Destroy(2889)
                gosub @SEARCHLIGHTS  
                
                while true
                wait 0
                
                    //Verificando atividade do mod
                    0AAA: 0@ = thread 'MAF4' pointer    //Missão black project
                    077E: get_active_interior_to 1@     //Valor de interior
                    if and
                    8118:   not actor $PLAYER_ACTOR dead
                    8741:   not actor $PLAYER_ACTOR busted
                    not 0@ > 0  //Não estar na missão black project
                    0039:   1@ == 0 //Não estar em interior
                    then
                        if and
                        80EC:   not actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0  
                        8154:   not actor $PLAYER_ACTOR in_zone 'REST'
                        then
                            for 1@ = 0 to 25 step 5
                                Object.Destroy(3@(1@,1i))
                                Object.Destroy(4@(1@,1i))
                                Object.Destroy(5@(1@,1i))
                                if
                                    06B3:   searchlight 2@(1@,1i) active
                                then
                                    06B2: destroy_searchlight 2@(1@,1i)
                                end    
                            end
                            break
                        end
                    else
                        wait 5000
                        for 1@ = 0 to 25 step 5
                            Object.Destroy(3@(1@,1i))
                            Object.Destroy(4@(1@,1i))
                            Object.Destroy(5@(1@,1i))
                            if
                                06B3:   searchlight 2@(1@,1i) active
                            then
                                06B2: destroy_searchlight 2@(1@,1i)
                            end    
                        end
                        break
                    end
                    
                    //Parâmetros do dia
                    00BF: 0@ = current_time_hours, 1@ = current_time_minutes
                    if and
                    0@ >= 5
                    21 > 0@                
                    
                    //Caso seja dia
                    then
                    
                        for 1@ = 0 to 25 step 5
                            if
                                06B3:   searchlight 2@(1@,1i) active
                            then
                                06B2:   destroy_searchlight 2@(1@,1i)
                            end
                        end
                    
                    //Caso seja noite    
                    else
                      
                        //Verificar se os holofotes estão corretamente ativos
                        for 1@ = 0 to 25 step 5
                            if and
                            86B3:   not searchlight 2@(1@,1i) active
                            0039:   6@(1@,1i) == 0
                            then
                                gosub @SEARCHLIGHTS
                            else
                                if and
                                06B3:   searchlight 2@(1@,1i) active
                                0039:   6@(1@,1i) == 1
                                then
                                    gosub @SEARCHLIGHTS
                                end
                            end
                        end
                        
                        //Sistema de detecção dos holofotes
                        if and
                        8500:   not player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                        856C:   not actor $PLAYER_ACTOR driving_police_car
                        80DD:   not actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                        810F:   not player $PLAYER_CHAR wanted_level > 2
                        then
                            for 1@ = 0 to 25 step 5
                                if and
                                03CA:   object 3@(1@,1i) exists
                                06B3:   searchlight 2@(1@,1i) active
                                06B7:   searchlight 2@(1@,1i) spotted_actor $PLAYER_ACTOR
                                then
                                    wait 500
                                    Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                                    break
                                end
                            end
                        end
                          
                        //Detecção de holoftes destruidos
                        //Verificando e destruindo holofotes
                        for 1@ = 0 to 25 step 5
                            071E: get_object 3@(1@,1i) health_to 0@
                            if and
                                5000 > 0@
                                8039:   not 6@(1@,1i) == 1
                            then
                                06B2: destroy_searchlight 2@(1@,1i)
                                066D: 0@ = attach_particle "SHOOTLIGHT" to_object 3@(1@,1i) with_offset 0.0 1.181 0.768 type 1
                                0006: 6@(1@,1i) = 1
                            end
                        end
                        //Se mais de um holofotes estiverem apagados
                        0@ = 0
                        for 1@ = 0 to 25 step 5
                            005A: 0@ += 6@(1@,1i)
                        end
                        if and
                        810F:   not player $PLAYER_CHAR wanted_level > 2
                        0029:   0@ >= 2
                        then
                            Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                        end
                        
                    end                
                end            
            end
        end  
    end

    :SEARCHLIGHTS
    wait 1000   //Garantir que o R69-searchlights seja carregado primeiro
    //Luzes 7
    06B1: 2@ = create_searchlight_at 103.946 1901.047 36.246 radius 0.5 target 108.51 1917.268 17.63 radius 10.5
    06B4: set_searchlight 2@ path_between 108.51 1917.268 17.63  and 135.323 1917.776 18.71 speed 0.5
    //Luzes 8
    06B1: 7@ = create_searchlight_at 342.5 1805.0 36.65 radius 0.5 target 292.0729 1820.5411 17.6714 radius 10.5  
    06B4: set_searchlight 7@ path_between 292.0729 1820.5411 17.6714 and 363.23 1984.76 17.68 speed 0.5
    //Luzes 9
    06B1: 12@ = create_searchlight_at 203.315 1958.966 16.8 radius 0.5 target 317.0321 1915.2159 17.6712 radius 10.5  
    06B4: set_searchlight 12@ path_between 317.0321 1915.2159 17.6712 and 231.39 2053.98 17.64 speed 0.5
    //Luzes 10
    06B1: 17@ = create_searchlight_at 342.5 1805.0 36.65 radius 0.5 target 293.7829 2027.2671 17.6406 radius 10.5
    06B4: set_searchlight 17@ path_between 293.7829 2027.2671 17.6406 and 227.34 2059.46 17.78 speed 0.5
    //Luzes 11
    06B1: 22@ = create_searchlight_at 342.5 1805.0 36.65 radius 0.5 target 302.03 1853.14 17.68 radius 10.5
    06B4: set_searchlight 22@ path_between 302.03 1853.14 17.68 and 294.3624 1989.0602 17.6406 speed 0.5
    //Luzes 12
    06B1: 27@ = create_searchlight_at 377.23 1978.96 36.35 radius 0.5 target 297.04 1980.71 17.64 radius 10.5
    06B4: set_searchlight 27@ path_between 297.04 1980.71 17.64 and 303.4079 1878.8132 17.6842 speed 0.5
                        
    //Outras considerações gerais das luzes
    for 1@ = 0 to 25 step 5
        06CA: attach_searchlight 2@(1@,1i) to_tower 5@(1@,1i) to_housing 4@(1@,1i) to_bulb 3@(1@,1i) with_offset 0.0 1.181 0.768
        0A02: set_searchlight 2@(1@,1i) lights_through_obstacles 0
        071F: set_object 3@(1@,1i) health_to 5000
        0875: set_object 3@(1@,1i) immune_to_nonplayer 1
        0006: 6@(1@,1i) = 0
    end
    return

    RenanMSV
    Mensagens Nível 4
    Mensagens Nível 4

    Plataforma : PC. Windows.
    Mensagens : 263
    Reputação : 38
    Localização : Cps - SP
    Link : goo.gl/BgNT9p

    Re: RealArea69 v0.6.2

    Mensagem por RenanMSV em Seg 04 Jan 2016, 00:10

    Pra verificar se um ped eh policial verifique o pedtype dele. Policiais tem o pedtype 6. Pedestres normais varia de 4 a outros valores.


    ____________________
    Não importa o quão pequeno você
    comece, apenas comece algo que
    importa.


    Mods cleo de minha autoria: https://db.tt/91oW1EWC
    Jogos de minha autoria: nenhum por enquanto
    ModLoader VIsual Editor WIP

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Seg 04 Jan 2016, 14:42

    Então, isso é suave, o que não sei é como selecionar um ped ou carro aleatório e verificar esses valores.

    israel
    Programador - Básico
    Programador - Básico

    Mensagens : 290
    Reputação : 26

    Re: RealArea69 v0.6.2

    Mensagem por israel em Seg 04 Jan 2016, 14:58



    ____________________
    " Aquele que não conhece a dor , jamais entenderá a verdadeira paz ! "

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Seg 04 Jan 2016, 18:20

    Nossa, vai ajudar e muito! Vlw Israel!

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Qua 06 Jan 2016, 22:57

    Progresso:
    12b) Peds policiais poderem entrar pelos portões da área 69 se tiverem veículos -> FEITO!
    (Vai ser colocado na próxima versão)

    Sobre soldados inteligentes na área 69:
    - Acham que usar o opcode "09ED: actor $soldado is_within_field_of_view_actor $3 " (óbvio que não vou usar a variável $soldado né) é suficiente para usar como detecção do CJ quando estiver de noite além dos holofotes? Exemplo: caso verem o player, ganha seis níveis de procurado.
    - Algum comportamento especial seria bom para aplicar neles quando o player estiver com níveis de procurado?

    Alguma sugestão a respeito?

    Vlw!

    Elyzandro
    Veterano
    Veterano

    Mensagens : 2728
    Reputação : 79

    Re: RealArea69 v0.6.2

    Mensagem por Elyzandro em Qua 06 Jan 2016, 23:56

    https://drive.google.com/folderview?id=0B37TrXDep9JwWGMtUnczQnQ3Q1U&usp=sharing
    Olha esse kct, tem que ficar baixando um por um, passa o link certo dessa desgraça.

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Qui 07 Jan 2016, 00:39

    Arrumado. Link para o arquivo em .rar agora. Achava que dava para baixar a pasta toda de uma vez...

    israel
    Programador - Básico
    Programador - Básico

    Mensagens : 290
    Reputação : 26

    Re: RealArea69 v0.6.2

    Mensagem por israel em Qui 07 Jan 2016, 00:56

    Agora sim. :v:


    ____________________
    " Aquele que não conhece a dor , jamais entenderá a verdadeira paz ! "

    Elyzandro
    Veterano
    Veterano

    Mensagens : 2728
    Reputação : 79

    Re: RealArea69 v0.6.2

    Mensagem por Elyzandro em Qui 07 Jan 2016, 01:51

    Agora sim :v:
    Talvez amanhã eu instale pra ver como tá.

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Sab 09 Jan 2016, 18:34

    v0.3
    - Colocado um fix para evitar objetos presos dentro do jogo;
    - Agora policiais ou quem esteja em um poderá abrir os portões extenos da área 69;
    - JetPack colocado na área 69 já antes de ter completado a missão 'Black Project';
    - Todo o script não funcionará na missão 'Black Project';
    - Mais uma entrada especial da missão 'Black Project' colocada;
    - Outros pequenos ajustes e error no R69-enters.

    Novo source do R69-enters.cs

    Código:
    {$CLEO .cs}
    0000: NOP
    thread 'R69-Ent'

    //Constantes
    const
       
        //Centro dos portões 1 e 2
        CENTERA_X = 135.095
        CENTERA_Y = 1941.32
        //Coordenada de portão 1 aberto
        DOOR1OP_X = 145.475
        DOOR1OP_Y = 1941.32
        DOOR1OP_Z = 18.335
        //Coordenada de portão 2 aberto
        DOOR2OP_X = 124.715
        DOOR2OP_Y = 1941.32
        DOOR2OP_Z = 18.335
        //Coordenada de portão 1 fechado
        DOOR1CL_X = 139.075
        DOOR1CL_Y = 1941.32
        DOOR1CL_Z = 18.335
        //Coordenada de portão 2 fechado
        DOOR2CL_X = 131.115
        DOOR2CL_Y = 1941.32
        DOOR2CL_Z = 18.335
       
        //Centro dos portões 3 e 4
        CENTERB_X = 285.641
        CENTERB_Y = 1821.39
        //Coordenada de portão 3 aberto
        DOOR3OP_X = 285.641 
        DOOR3OP_Y = 1811.81 
        DOOR3OP_Z = 16.651 
        //Coordenada de portão 4 aberto
        DOOR4OP_X = 285.641 
        DOOR4OP_Y = 1830.97 
        DOOR4OP_Z = 16.651 
        //Coordenada de portão 3 fechado
        DOOR3CL_X = 285.641 
        DOOR3CL_Y = 1817.41 
        DOOR3CL_Z = 16.651
        //Coordenada de portão 4 fechado
        DOOR4CL_X = 285.641 
        DOOR4CL_Y = 1825.37
        DOOR4CL_Z = 16.651
       
        //Blastdoors
        BLAST1OP_X = 207.842
        BLAST2OP_X = 219.941
        BLAST1CL_X = 211.842
        BLAST2CL_X = 215.941
        BLAST_Y = 1874.571
        BLAST_Z = 13.903

    end

    // Jetpack já inserido no local da área 69 antes de se ter completado a missão Black Project
    if
    not $Toreno_Total_Passed_Missions > 7
    then
        032B: 10@ = create_weapon_pickup #JETPACK type 15 ammo 0 at 268.7 1884.1 -30.085
    end

    0AB1: call_scm_func @FLSOBJ 0

    //Iniciar loop infinito do script
    while true   
        wait 0
        //Primeiros parâmetros: fora de interior e não estar na missão Black Project
        0AAA: 0@ = thread 'MAF4' pointer    //Missão black project
        077E: get_active_interior_to 6@    //Verificar interior
        //Verificar personagem e se não está em interior
        if and
        0039:  6@ == 0
        not 0@ > 0
        Player.Defined($PLAYER_CHAR)
        then
            //Remoção de possíveis objetos presos ao jogo!!!   
            //Verificar se o personagem está na região da área 69
            if or
            00EC:  actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0 
            0154:  actor $PLAYER_ACTOR in_zone 'REST'
            then
               
                //Colocar e ativar portões da área 69
                1@ = Object.Create(985, 139.075, 1941.32, 18.335)
                Object.Angle(1@) = 0.0
                2@ = Object.Create(986, 131.115, 1941.32, 18.335)
                Object.Angle(2@) = 0.0
                3@ = Object.Create(985, 285.641, 1817.41, 16.651)
                Object.Angle(3@) = 270.0
                4@ = Object.Create(986, 285.641, 1825.37, 16.651)
                Object.Angle(4@) = 270.0
               
                //Outros parâmetos
                0A24: enable_military_zones_wanted_level 0
                07A8: enable_area69_sam 1
                0006: 5@ = 1    //Verificação de que sistema de defesa aérea está funcionando
               
                //Tempo de duração do blastdoors
                0006: 32@ = 30000
               
                //Parâmetros para a porta de acesso ao lab
                060A: create_decision_maker_type 0 store_to 8@ // decision\allowed\m_.ped files
                0247: load_model #WMOSCI
                0247: load_model #A51_LABDOOR
                038B: load_requested_models
                //Create actor in lab         
                7@ = Actor.Create(CivMale, #WMOSCI, 276.57, 1854.53, 7.75)
                0249: release_model #WMOSCI
                Actor.Angle(7@) = 175.15
                0638: AS_actor 7@ stay_put 1 
                060B: set_actor 7@ decision_maker_to 8@
                //Create lab's door
                9@ = Object.Create(#A51_LABDOOR, 268.66, 1864.059, 7.5)
                0249: release_model #A51_LABDOOR
                0006:  11@ = 0 //Parâmetro de verificação de situação do Lab's door       
               
                //Scripts das entradas da área 69
                while true
                    wait 0
             
                    //Portões de entrada
                    if and
                    03CA:  object 1@ exists
                    03CA:  object 2@ exists
                    03CA:  object 3@ exists
                    03CA:  object 4@ exists
                    then
                        //primeiro portão
                        0AB1: call_scm_func @DOORS 23 1@ 2@ CENTERA_X CENTERA_Y 6.0 12.0 DOOR1OP_X DOOR1OP_Y DOOR1OP_Z DOOR2OP_X DOOR2OP_Y DOOR2OP_Z DOOR1CL_X DOOR1CL_Y DOOR1CL_Z DOOR2CL_X DOOR2CL_Y DOOR2CL_Z 0.1 0.0 0.0
                        //segundo portão
                        0AB1: call_scm_func @DOORS 23 3@ 4@ CENTERB_X CENTERB_Y 12.0 6.0 DOOR3OP_X DOOR3OP_Y DOOR3OP_Z DOOR4OP_X DOOR4OP_Y DOOR4OP_Z DOOR3CL_X DOOR3CL_Y DOOR3CL_Z DOOR4CL_X DOOR4CL_Y DOOR4CL_Z 0.0 0.1 0.0   
                    else
                        Object.Destroy(1@)
                        Object.Destroy(2@)
                        Object.Destroy(3@)
                        Object.Destroy(4@)
                        Object.Destroy(9@)
                        Actor.RemoveReferences(7@)
                        0A24: enable_military_zones_wanted_level 0
                        07A8: enable_area69_sam 1
                        break
                    end
               
                    // Área de saída do jetpack
                    if and
                    03CA:  object $2670 exists
                    00EC:  actor $PLAYER_ACTOR sphere 0 near_point 269.081 1884.109 radius 8.0 8.0
                    0A0C:  player $PLAYER_CHAR on_jetpack
                    then
                        034E: move_object $2670 to 276.14 1884.06 15.924 speed 0.05 0.0 0.0 collision_check 0
                    else
                        034E: move_object $2670 to 268.664 1884.06 15.925 speed 0.05 0.0 0.0 collision_check 0
                    end
               
                    //Entrada de ventilação
                    if  03CA:  object $Object_M_A51_VENTCOVERB exists
                    then
                        Object.Destroy($Object_M_A51_VENTCOVERB)
                    end
               
                    //Desabilitação do sistema de defesa aérea
                    if  0039:  5@ == 1               
                    then
                        //Verificação: posição do player para apertar botões para DESATIVAÇÃO
                        if  0102:  actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                        then
                            0ACC: "Press 'enter/exit vehicle' to DISABLE the air defense system." time 100
                            if and
                            0102:  actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                            00E1:  player 0 pressed_key 15
                            then
                                //Desativando defesa aérea da área 69
                                0AB1: call_scm_func @ACTIVE 0
                                0ACD: "Air defense system disabled." time 3000
                                07A8: enable_area69_sam 0
                                0006: 5@ = 0
                                wait 3000
                            end
                        end                   
                    else
                        //Verificação: posição do player para apertar botões para DESATIVAÇÃO
                        if  0102:  actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                        then
                            0ACC: "Press 'enter/exit vehicle' to ENABLE the air defense system." time 100
                            if and
                            0102:  actor $PLAYER_ACTOR in_sphere 213.1556 1822.714 6.4141 radius 2.0 2.0 10.0 sphere 1 stopped_on_foot
                            00E1:  player 0 pressed_key 15
                            then
                                0AB1: call_scm_func @ACTIVE 0
                                //Ativando defesa aérea da área 69
                                0ACD: "Air defense system enabled." time 3000
                                07A8: enable_area69_sam 1
                                0006: 5@ = 1
                                wait 3000
                            end
                        end                   
                    end
               
                    //Portão pneumático
                    if and
                    03CA:  object $Object_M_A51_BLASTDOORL exists
                    03CA:  object $Object_M_A51_BLASTDOORR exists
                    then
                        //Verificar se o portão está em situação de ficar aberto
                        if  8029:  not 32@ >= 30000
                        then
                            //Abrindo os blastdoors
                            034E: move_object $Object_M_A51_BLASTDOORR to BLAST1OP_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                            034E: move_object $Object_M_A51_BLASTDOORL to BLAST2OP_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                        else                           
                            //Ativação dos blastdoors por dentro
                            if  0102:  actor $PLAYER_ACTOR in_sphere 246.9874 1860.8265 14.084 radius 2.0 2.0 3.0 sphere 1 stopped_on_foot
                            then
                                0ACC: "Press 'enter/exit vehicle' to open the blastdoors." time 100
                                if 00E1:  player 0 pressed_key 15
                                then
                                    //Abrindo os blastdoors
                                    0AB1: call_scm_func @ACTIVE 0
                                    034E: move_object $Object_M_A51_BLASTDOORR to BLAST1OP_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                    034E: move_object $Object_M_A51_BLASTDOORL to BLAST2OP_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                    0ACD: "The blastdoors is opening. You have few time to go out." time 4000
                                    0006: 32@ = 0
                                    wait 4000
                                else
                                    //Fechando os blastdoors
                                    034E: move_object $Object_M_A51_BLASTDOORR to BLAST1CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                    034E: move_object $Object_M_A51_BLASTDOORL to BLAST2CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                end
                            else
                                //Ativação dos blastdoors por fora, se não estiver sendo procurado
                                if
                                not Player.WantedLevel($PLAYER_CHAR) > 2
                                then
                                    if  0102:  actor $PLAYER_ACTOR in_sphere 211.4867 1812.2637 21.8594 radius 2.0 2.0 3.0 sphere 1 stopped_on_foot
                                    then
                                        0ACC: "Press 'enter/exit vehicle' to open the blastdoors." time 100
                                        if  00E1:  player 0 pressed_key 15
                                        then
                                            //Abrindo os blastdoors
                                            0AB1: call_scm_func @ACTIVE 0
                                            034E: move_object $Object_M_A51_BLASTDOORR to BLAST1OP_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                            034E: move_object $Object_M_A51_BLASTDOORL to BLAST2OP_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                            0006: 32@ = 0
                                            0ACD: "The blastdoors is opening. You have few time to go in." time 4000
                                            wait 4000
                                        else
                                            //Fechando os blastdoors
                                            034E: move_object $Object_M_A51_BLASTDOORR to BLAST1CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                            034E: move_object $Object_M_A51_BLASTDOORL to BLAST2CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                        end
                                    else
                                        //Fechando os blastdoors
                                        034E: move_object $Object_M_A51_BLASTDOORR to BLAST1CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                        034E: move_object $Object_M_A51_BLASTDOORL to BLAST2CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                    end
                                else
                                    //Fechando os blastdoors
                                    034E: move_object $Object_M_A51_BLASTDOORR to BLAST1CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                    034E: move_object $Object_M_A51_BLASTDOORL to BLAST2CL_X BLAST_Y BLAST_Z speed 0.05 0.0 0.0 collision_check 0
                                end     
                            end   
                        end
                    end
                   
                    //Porta do laboratório de acesso ao jetpack - pegar keycard
                    if  0039:  11@ == 0
                    then
                        if  0118:  actor 7@ dead
                        then
                            if  81A6:  not actor $PLAYER_ACTOR sphere 0 in_cube_cornerA 283.0 1852.2 13.1 cornerB 264.0 1864.0 8.7 on_foot
                            then
                                7@ = Actor.Create(CivMale, #WMOSCI, 276.57, 1854.53, 7.75)
                                0249: release_model #WMOSCI
                                Actor.Angle(7@) = 175.15
                                0638: AS_actor 7@ stay_put 1 
                                060B: set_actor 7@ decision_maker_to 8@
                            end
                        else
                            if and
                            //Verificar se player já perseguido
                            01A6:  actor $PLAYER_ACTOR sphere 0 in_cube_cornerA 283.0 1852.2 13.1 cornerB 264.0 1864.0 8.7 on_foot
                            Player.WantedLevel($PLAYER_CHAR) > 2
                            then
                                0AB1: call_scm_func @GETKEYCARD 1 7@ retorna 12@ 11@
                            else
                                if or
                                //Verificar se player está mirando ou atacando cientista
                                051A:  actor 7@ damaged_by_actor $PLAYER_ACTOR
                                0457:  player $PLAYER_CHAR aiming_at_actor 7@
                                then
                                    Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                                    0AB1: call_scm_func @GETKEYCARD 1 7@ retorna 12@ 11@
                                else
                                    if and
                                    //Verificar se o player está atacando área de pesquisa do cientista
                                    02D6:  actor $PLAYER_ACTOR fires_weapon 0 in_rectangle_cornerA 282.25 1852.36 cornerB 264.28 1863.69
                                    01A6:  actor $PLAYER_ACTOR sphere 0 in_cube_cornerA 283.0 1852.2 13.1 cornerB 264.0 1864.0 8.7 on_foot
                                    then
                                        Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                                        0AB1: call_scm_func @GETKEYCARD 1 7@ retorna 12@ 11@
                                    else
                                        if and
                                        //Caso o ator estiver morto
                                        81A6:  not actor $PLAYER_ACTOR sphere 0 in_cube_cornerA 283.0 1852.2 13.1 cornerB 264.0 1864.0 8.7 on_foot
                                        0118:  actor 7@ dead
                                        then
                                            //Recriar o ator
                                            7@ = Actor.Create(CivMale, #WMOSCI, 276.57, 1854.53, 7.75)
                                            0249: release_model #WMOSCI
                                            Actor.Angle(7@) = 175.15
                                            0638: AS_actor 7@ stay_put 1 
                                            060B: set_actor 7@ decision_maker_to 8@
                                        else
                                            //"Animar o ator"
                                            0605: actor 7@ perform_animation "ATM" IFP "PED" framedelta 4.0 loop 0 lockX 0 lockY 0 lockF 0 time 2000
                                        end
                                    end
                                end
                            end
                        end
                    end
                    //Porta do laboratório de acesso ao jetpack - pegar keycard
                    if and
                    0039:  11@ == 1
                    Pickup.Picked_up(12@)
                    then
                        0006:  11@ = 2
                    end
                    //Porta do laboratório de acesso ao jetpack - abrir porta
                    if and
                    03CA:  object 9@ exists
                    0039:  11@ == 2
                    then
                        if
                        0102:  actor $PLAYER_ACTOR in_sphere 267.015 1862.51 7.76 radius 2.0 2.0 2.0 sphere 1 stopped_on_foot
                        then
                            0ACC: "Press 'enter/exit vehicle' to open the lab's door." time 100
                            if and
                            0102:  actor $PLAYER_ACTOR in_sphere 267.015 1862.51 7.76 radius 2.0 2.0 2.0 sphere 1 stopped_on_foot
                            00E1:  player 0 pressed_key 15
                            then
                                0605: actor $PLAYER_ACTOR perform_animation "ATM" IFP "PED" framedelta 8.0 loop 0 lockX 0 lockY 0 lockF 0 time 2500
                                wait 2500
                                034E: move_object 9@ to 268.66 1864.059 12.2 speed 0.0 0.0 0.08 collision_check 0
                                0006:  11@ = 3
                                0ACD: "Lab's door is open." time 4000
                            end
                        end
                    end
                    //Porta do laboratório de acesso ao jetpack - porta abrindo
                    if  0039:  11@ == 3
                    then
                        034E: move_object 9@ to 268.66 1864.059 12.2 speed 0.0 0.0 0.08 collision_check 0   
                    end               
                   
                    //Invasão noturna!!!
                    //Parâmetros do dia
                    00BF: 13@ = current_time_hours, 14@ = current_time_minutes
                    if and
                    13@ >= 5
                    21 > 13@               
                    //Caso seja dia
                    then
                        if or
                        0500:  player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                        056C:  actor $PLAYER_ACTOR driving_police_car
                        00DD:  actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                        //Disfarçado
                        then
                            if  not Player.WantedLevel($PLAYER_CHAR) > 2
                            then
                                //Não Procurado
                                0A24: enable_military_zones_wanted_level 1   
                            else
                                //Procurado
                                0A24: enable_military_zones_wanted_level 0
                            end
                        else
                            //Caso estiver de dia e o player não estiver disfarçado
                            0A24: enable_military_zones_wanted_level 0
                        end               
                    //Caso seja noite
                    else
                        if and
                        8500:  not player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
                        856C:  not actor $PLAYER_ACTOR driving_police_car
                        80DD:  not actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
                        //Não disfarçado
                        then
                            if and
                            80DF:  not actor $PLAYER_ACTOR driving
                            8A0C:  not player $PLAYER_CHAR on_jetpack
                            not Player.WantedLevel($PLAYER_CHAR) > 2
                            //Se não estiver sendo procurado e não estiver num veículo
                            then
                                0A24: enable_military_zones_wanted_level 1
                            //Se estiver sendo procurado ou estiver num veículo
                            else
                                0A24: enable_military_zones_wanted_level 0
                            end
                        //Disfarçado
                        else
                            //Verificando se está procurado ou não
                            if  not Player.WantedLevel($PLAYER_CHAR) > 2
                            then
                                //Não Procurado
                                0A24: enable_military_zones_wanted_level 1
                            else
                                //Procurado
                                0A24: enable_military_zones_wanted_level 0                   
                            end
                        end 
                    end
                   
                    //Não invada a área 69 se estiver sendo procurado!!!
                    :SEARCHLIGHTS14
                    if and
                        0154:  actor $PLAYER_ACTOR in_zone 'REST'  // Restricted Area
                        Player.WantedLevel($PLAYER_CHAR) > 2   
                    then
                    Player.SetMinWantedLevel($PLAYER_CHAR, 6)
                    end
                   
                    //Verificar personagem está ativo, não está em um interior e não está na missão black project
                    0AAA: 0@ = thread 'MAF4' pointer    //Missão black project
                    077E: get_active_interior_to 6@
                    if and
                    not 0@ > 0
                    0039:  6@ == 0
                    8118:  not actor $PLAYER_ACTOR dead
                    8741:  not actor $PLAYER_ACTOR busted
                    then
                        //Verificar personagem e está na região da área 69
                        if or
                        00EC:  actor $PLAYER_ACTOR sphere 0 near_point 193.3863 1851.257 radius 500.0 500.0 
                        0154:  actor $PLAYER_ACTOR in_zone 'REST'
                        then
                            continue
                        else
                            Object.Destroy(1@)
                            Object.Destroy(2@)
                            Object.Destroy(3@)
                            Object.Destroy(4@)
                            Object.Destroy(9@)
                            Actor.RemoveReferences(7@)
                            0A24: enable_military_zones_wanted_level 0
                            07A8: enable_area69_sam 1
                            break   
                        end
                    else
                        Object.Destroy(1@)
                        Object.Destroy(2@)
                        Object.Destroy(3@)
                        Object.Destroy(4@)
                        Object.Destroy(9@)
                        Actor.RemoveReferences(7@)
                        0A24: enable_military_zones_wanted_level 0
                        07A8: enable_area69_sam 1
                        break
                    end
                   
                end                       
            end
        end
    end

    :FLSOBJ
    0A8D: 29@ = read_memory 0xB7449C size 4 virtual_protect 0
    000A: 29@ += 0x4
    0A8D: 29@ = read_memory 29@ size 4 virtual_protect 0
    for 30@ = 0 to 89344 step 0x100
        0A8D: 31@ = read_memory 29@ size 1 virtual_protect 0
        000A: 29@ += 0x1
        if and
            0029:  31@ >= 0x00
            001B:  0x80 > 31@
        then
            005A: 31@ += 30@
            0984: 0@ = object 31@ model
            if
            04E5:  object 31@ near_point 193.3863 1851.257 radius 500.0 500.0 sphere 0
            then
                if or
                0039: 0@ == 985
                0039: 0@ == 986
                0039: 0@ == 2887
                0039: 0@ == 2888
                0039: 0@ == 2889
                0039: 0@ == 2951
                then
                    0108: destroy_object 31@ 
                end
            end
        end
    end
    0AB2: ret 0 0

    :ACTIVE
    //ativando animação
    04ED: load_animation "CASINO"
    repeat
        wait 0
    until 04EE:  animation "CASINO" loaded               
    //Fazendo a animação
    0615: define_AS_pack_begin 0@
    0605: actor -1 perform_animation "SLOT_BET_02" IFP "CASINO" framedelta 4.0 loop 0 lockX 0 lockY 0 lockF 0 time -1
    0616: define_AS_pack_end 0@
    0618: assign_actor $PLAYER_ACTOR to_AS_pack 0@
    061B: remove_references_to_AS_pack 0@
    04EF: release_animation "CASINO"
    wait 1000  //Tempo para clicar no botão antes de qualquer ativação real
    0AB2: ret 0 0

    :DOORS
    //Verificar se está no ponto e não é procurado
    if and
    00EC:  actor $PLAYER_ACTOR sphere 0 near_point 2@ 3@ radius 4@ 5@
    810F:  not player $PLAYER_CHAR wanted_level > 2
    then
    //Verificar se é um "policial"
        if or
        0500:  player $PLAYER_CHAR skin == "POLICETR" on_bodypart 17
        056C:  actor $PLAYER_ACTOR driving_police_car
        00DD:  actor $PLAYER_ACTOR driving_car_with_model #PATRIOT
        then
            //Abrir portões
            034E: move_object 0@ to 6@ 7@ 8@ speed 18@ 19@ 20@ collision_check 0
            034E: move_object 1@ to 9@ 10@ 11@ speed 18@ 19@ 20@ collision_check 0
        else
            gosub @COPSON69
        end
    else
        gosub @COPSON69
    end
    0AB2: ret 0 0

    //Ver se tem policiais nos portões da 69
    :COPSON69
    0A8D: 29@ = read_memory 0xB74490 size 4 virtual_protect 0
    000A: 29@ += 0x4
    0A8D: 29@ = read_memory 29@ size 4 virtual_protect 0
    for 30@ = 0 to 35584 step 0x100
        0A8D: 31@ = read_memory 29@ size 1 virtual_protect 0
        000A: 29@ += 0x1
        if and
            0029:  31@ >= 0x00
            001B:  0x80 > 31@
        then
            005A: 31@ += 30@
            089F: get_actor 31@ pedtype_to 28@
            if and
            87D6:  31@ <> $player_actor
            00EC:  actor 31@ sphere 0 near_point 2@ 3@ radius 4@ 5@
            00DF:  actor 31@ driving
            then
                if or
                056C:  actor 31@ driving_police_car
                00DD:  actor 31@ driving_car_with_model #PATRIOT
                0039:  28@ == 6
                then
                    //Abrir portões
                    034E: move_object 0@ to 6@ 7@ 8@ speed 18@ 19@ 20@ collision_check 0
                    034E: move_object 1@ to 9@ 10@ 11@ speed 18@ 19@ 20@ collision_check 0
                    return
                end
            end
        end
    end
    //Fechar portões
    034E: move_object 0@ to 12@ 13@ 14@ speed 18@ 19@ 20@ collision_check 0
    034E: move_object 1@ to 15@ 16@ 17@ speed 18@ 19@ 20@ collision_check 0
    return

    :GETKEYCARD
    wait 500 //Apenas para dar possível situação de cientista morto
    if
    8118:  not actor 0@ dead
    then
        05C4: AS_actor 0@ hands_up 20000 ms
        03CF: load_wav 13600 as 2
        repeat
            wait 0
        until  03D0:  wav 2 loaded
        0949: link_wav 2 to_actor 0@
        03D1: play_wav 2
        00BC: show_text_highpriority GXT 'DES8_AA' time 2000 flag 1  // ~z~Please, no more violence! Take my pass card and go!
    end
    04C4: store_coords_to 11@ 12@ 13@ from_actor 0@ with_offset 0.0 1.0 0.1
    1@ = Pickup.Create(#KEYCARD, 3, 11@, 12@, 13@)
    0AB2: ret 2 1@ 1

    Questões:
    - Alguém sabe, conhece alguém que saiba ou ao menos tenha uma referencia sobre o funcionamento dos holofotes com searchlights? Tem hora que no jogo funcionam seis, outras oito, e outras até bem menos do que seis?
    - No Open Limit Adjuster tem um extensor do limite de searchlights no jogo (ver item 8 no que 'se planeja para o futuro') mas isso não ajuda no caso do funcionamento deles (eles são ativos, mas não se movimentam e nem linkam com os holofotes).

    - Acho que chegou a hora de começar a colocar ais vida nesse e por soldados dentro desse mod! Espero que o faça pra próxima versão beta.

    Matheus22567
    Mensagens Nível 6
    Mensagens Nível 6

    Plataforma : PC
    Mensagens : 1785
    Reputação : 16
    Idade : 16
    Localização : Rio Claro SP
    Link : http://youtube.com/samu22gamer

    Re: RealArea69 v0.6.2

    Mensagem por Matheus22567 em Sab 09 Jan 2016, 18:39

    Olha ta ficando gostoso em..


    ____________________
    PC:
    Processador: Dual Core G2030 3 GHz
    Memoria RAM: 4GB
    Placa mae: P8H61 LX2 R2.0
    Video: HD Graphics Family
    HD: 465GB
    fonte: 500W ATX sla oq




    Elyzandro
    Veterano
    Veterano

    Mensagens : 2728
    Reputação : 79

    Re: RealArea69 v0.6.2

    Mensagem por Elyzandro em Sab 09 Jan 2016, 18:43

    E eu ainda não instalei Fuch That Guy
    Vou instalar agora mesmo. :D

    Elyzandro
    Veterano
    Veterano

    Mensagens : 2728
    Reputação : 79

    Re: RealArea69 v0.6.2

    Mensagem por Elyzandro em Sex 22 Jan 2016, 00:22

    Bem bacana o mod, porém aqueles efeitos dos holofotes ligados demorou pra aparecer.
    E não sei se é o seu mod que está dando queda de frames ou o SAAC que instalei aqui, bem, creio que seja o SAAC.

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Sex 22 Jan 2016, 01:04

    @Elyzandro , os holofotes só funcionam de noite...

    Aqui não acho que demoram muito para falar a verdade...

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Sab 23 Jan 2016, 01:30

    v0.4
    - Sem mudanças nas funções do mod;
    - Parâmetros de funcionamento um pouco melhorados;
    - Novo script 'R69' que substitui o R69-searchlights e R69-searchlights-2 (na próxima versão ele também substituirá o R69-enters, o que o tornará o único script do mod).

    Estou conseguindo unir os scritps graças aos tópicos de tutoriais:
    http://brmodstudio.forumeiros.com/t3210-x-thread-memory
    http://brmodstudio.forumeiros.com/t4709-16-manuseamento-de-memorias-e-estruturas

    Tá ajudando pakas!

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Dom 24 Jan 2016, 15:48

    v0.5
    - Scripts unificados: R69-enters.cs e blackprojectfix.cs com R69.cs;
    - Opção de baixar blackprojectfix.cs separadamente.

    MUDANÇAS NO FUTURO DO MOD:
    1) Quero colocar um sistema de detecção com soldados que rondarem a área durante a noite. Devem verificar se o player está invadindo ou não (baseando em missões como 'Vertical Bird', 'Home in the Hills', etc;). Se descobrirem, vão te caçar até a morte;
    1.1) Somente haverá níveis de procurado se você já vier para a área com mais de uma estrela ou fugir sendo perseguido da área 69;
    2) Outros personagens dentro da área: cientístas, trabalhadores, etc.;
    3) Alguns veículos a mais (alguns adicionados e secretos inclusive, atráves da adição pelo Fastman's Limit Adjuster por exemplo);
    4) Um jetpack dentro da área antes da conclusão das missões ao seu respeito para ter motivos do player invadi-lá (FEITO);
    5) Outros Easter Eggs e elementos únicos dentro dela (opcional);
    6) Um sistema mais inteligente dos holofotes, sendo mais semelhante ao da missão 'Black Project' (opcional);
    7) Sistemas de sons de alarmas, de abertura do portão pneumático, da mulherzinha falando na missão (que é bem engraçado) etc. (opcional);
    8) Procurar consertar um bug dos holofotes, que, se tem mais de seis ativos, os excedentes não se mexem e vigiam o local, ficando parados. O Open Limit Adjuster aumentou o limite de searchlights (ScriptSearchLights) que podem ser ativos (pelo opcode 06B1). Seria possível fazer isso para os opcodes 06CA e 06B4?;
    9) Soldados fazendo rondas nas periferias da área 69 com ou sem veículos (opcional);
    10) Eliminar os policiais comuns que surgem do nada na área 69 quando se tem mais de duas estrelas ou transformá-los em soldados armados com M4 (isso não vai mais ser necessário pois não haverá mais níveis de procurado, com excessões já citadas, na área 69);
    11) Quando procurado, os holofotes te perseguem. Fiz isso, deu crash quando o player morria;

    DOWNLOADS
    - Mod: https://drive.google.com/file/d/0B37TrXDep9JwdnIyVVdLUlRaUUk/view?usp=sharing
    - BlackProjectFix (fix separado da missão 'Black Project') + Sources (R69.cs e blackprojectfix.cs):   https://drive.google.com/folderview?id=0B37TrXDep9JwalFVd0IwR05NY00&usp=sharing

    - Quem quiser ver o soruce só abrir o link acima;

    - Peço que se puderem testarem esse mod pra verificar possíveis bugs agradeço;
    - Quem tiver sugestões de melhorias agradeço ainda mais!

    Und
    Mensagens Nível 4
    Mensagens Nível 4

    Mensagens : 258
    Reputação : 10

    Re: RealArea69 v0.6.2

    Mensagem por Und em Seg 25 Jan 2016, 15:01

    Minha sugestão de melhoria é que além de ter novos veicúlos(adioncados, não substituidos)tenha skins tambem.

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Seg 25 Jan 2016, 16:39

    @Und , skins é mais suave colocar, só ter um cleo e o arquivos da skin, até penso em fazer algo assim. Mas Mas carros adicionados depende do Fastman92 , o que não me agrada nada (sinceramente não gosto nada dele, pois tem que ficar editando linhas do que adicionar e as totais conversões feitas nele, SAxVCxLC e Underground por exemplo, ficam impossíveis de colocar outros mods).

    RafaQN
    Mensagens Nível 2
    Mensagens Nível 2

    Mensagens : 97
    Reputação : 12
    Idade : 23
    Localização : São Paulo - SP

    Re: RealArea69 v0.6.2

    Mensagem por RafaQN em Ter 26 Jan 2016, 21:56

    v0.5.1
    - Retirado o blackprojectfix : script dessa parte bem mal pensado;
    - Blackprojectfix volta a ser separado

    Junior_Djjr
    Scripter CLEO - Avançado
    Scripter CLEO - Avançado

    Título : Junior, o periquito.
    Plataforma : PC
    Mensagens : 19529
    Reputação : 539
    Idade : 21
    Localização : Ibitinga - SP
    Link : www.MixMods.com.br

    Re: RealArea69 v0.6.2

    Mensagem por Junior_Djjr em Qua 27 Jan 2016, 01:04

    Bota os soldados rondando a noite (usar scmpath? nunca usei ele, acho q ele serviria pra isso) e use esse simples e lindo opcode:
    Código:
    0364:  actor 0@ spotted_actor $PLAYER_ACTOR

    Conteúdo patrocinado

    Re: RealArea69 v0.6.2

    Mensagem por Conteúdo patrocinado Hoje à(s) 02:24


      Data/hora atual: Seg 05 Dez 2016, 02:24