Compartilhe
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Título : Carinha que mora logo ali
Mensagens : 386
Reputação : 94
Desde : 07/03/2017
Localização : BH - MG
Link : http://emcodigo.blogspot.com.br/
Ver perfil do usuáriohttp://asvezesanime.blogspot.com.br/

Efeito de cor na tela ao receber dano ( corrigido )

em Qua 09 Ago 2017, 15:31

"Tirado do God Of War?"

Este mod faz com que quando o player tome dano uma borda de cor vermelha apareça nos cantos da tela, caso tenha colete apenas uma borda escura
O script cria um arquivo ini ao usar a primeira vez onde pode ser feitos alguns ajustes de tempo e intensidade da cor.

Correções

  • Adicionado e efeito ao receber dano usando colete
  • Efeito mais discreto
  • Melhoria no efeito de transição
  • Ajustes mais precisos
  • Melhoria nas texturas


Link versão corrigida



Source:

Código:

SCRIPT_START
{
    NOP

    WAIT 3000

    LVAR_INT scplayer
    LVAR_INT PrevLife NextLife MaxLife Counter AlfaColor
    LVAR_INT iniAlfa iniAlfaMax iniShowGain effectSpeed temp

    GET_PLAYER_CHAR 0 scplayer
    GET_CHAR_HEALTH scplayer MaxLife
    PrevLife = MaxLife

    GOSUB LoadIniFile

    Danger_Sprite:
        WAIT 0
        IF IS_PLAYER_PLAYING 0
            GET_CHAR_HEALTH scplayer NextLife
            IF NOT (PrevLife = NextLife)
                IF NOT (MaxLife = NextLife)
                    LOAD_TEXTURE_DICTIONARY DANGER
                    LOAD_ALL_MODELS_NOW
                    IF (PrevLife > NextLife)
                        LOAD_SPRITE 1 "RED"
                        GOSUB Function_Draw_Effect
                    ELSE
                        IF (iniShowGain = 1)
                            LOAD_SPRITE 1 "GREEN"
                            GOSUB Function_Draw_Effect
                        ENDIF
                    ENDIF
                    REMOVE_TEXTURE_DICTIONARY
                ENDIF
                PrevLife = NextLife
            ENDIF
            IF TEST_CHEAT "DNCINI"
                GOSUB LoadIniFile
                PRINT_HELP_STRING "Danger Color: Reloaded!"
            ENDIF
        ENDIF
    GOTO Danger_Sprite
    TERMINATE_THIS_CUSTOM_SCRIPT

    Function_Draw_Effect:
        USE_TEXT_COMMANDS 1
        Counter = 0
        WHILE (Counter <= effectSpeed)
            Counter ++
            IF (AlfaColor >= iniAlfaMax)
                AlfaColor = 0
            ELSE
                AlfaColor += iniAlfa
            ENDIF
            DRAW_SPRITE 1 319.5 217.5 672.0 477.0 255 255 255 AlfaColor
            WAIT 0
        ENDWHILE
        USE_TEXT_COMMANDS 0
    RETURN

    LoadIniFile:
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "On" temp
            temp = 1
            WRITE_INT_TO_INI_FILE temp "cleo\Danger Effect ( Um Geek ).ini" "Settings" "On"
        ELSE
            SWITCH (temp)
                CASE -1
                    TERMINATE_THIS_CUSTOM_SCRIPT
                    BREAK
                CASE 0
                    WHILE NOT TEST_CHEAT "DNCON"
                        WAIT 0
                    ENDWHILE
                    PRINT_HELP_STRING "Danger Color: ON!"
                    BREAK
            ENDSWITCH
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Level" iniAlfa
            iniAlfa = 5
            WRITE_INT_TO_INI_FILE iniAlfa "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Level"
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Effect_Speed"  effectSpeed
            effectSpeed = 60
            WRITE_INT_TO_INI_FILE effectSpeed "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Effect_Speed"
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Max"  iniAlfaMax
            iniAlfaMax = 200
            WRITE_INT_TO_INI_FILE iniAlfaMax "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Max"
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Show_life_reset" iniShowGain
            iniShowGain = 0
            WRITE_INT_TO_INI_FILE iniShowGain "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Show_life_reset"  
        ENDIF        
    RETURN
}
SCRIPT_END

Source atualizado:

Código:

SCRIPT_START
{
    NOP

    WAIT 3000

    LVAR_INT scplayer //timer nextTimer seconds soundEffect soundBGM
    LVAR_INT PrevLife NextLife MaxLife Counter AlfaColor PrevArmor NextArmor MaxArmor
    LVAR_INT iniAlfaMin iniAlfaMax iniShowGain //iniSoundEnable iniSoundVol gtimer sectime seconds
    LVAR_INT effectLevel temp

    GET_PLAYER_CHAR 0 scplayer
    GET_CHAR_HEALTH scplayer MaxLife
    GET_CHAR_ARMOUR scplayer MaxArmor

    PrevLife = MaxLife
    PrevArmor = MaxArmor
    
    GOSUB LoadIniFile

    Danger_Sprite:
        WAIT 0
        IF IS_PLAYER_PLAYING 0
            //--
            GET_CHAR_HEALTH scplayer NextLife
            IF NOT (PrevLife = NextLife)
                IF NOT (MaxLife = NextLife)
                    LOAD_TEXTURE_DICTIONARY DANGER
                    LOAD_ALL_MODELS_NOW
                    IF (PrevLife > NextLife)
                        LOAD_SPRITE 1 "RED"
                        GOSUB Function_Draw_Effect
                    ELSE
                        IF (iniShowGain = 1)
                            LOAD_SPRITE 1 "GREEN"
                            GOSUB Function_Draw_Effect
                        ENDIF
                    ENDIF
                    REMOVE_TEXTURE_DICTIONARY
                ENDIF
                PrevLife = NextLife
            ENDIF
            //--
            GET_CHAR_ARMOUR scplayer NextArmor
            IF NOT (PrevArmor = NextArmor)
                IF NOT (MaxArmor = NextArmor)
                    LOAD_TEXTURE_DICTIONARY DANGER
                    LOAD_ALL_MODELS_NOW
                    IF (PrevArmor> NextArmor)
                        LOAD_SPRITE 1 "BLACK"
                        GOSUB Function_Draw_Effect
                    ELSE
                        IF (iniShowGain = 1)
                            LOAD_SPRITE 1 "GREEN"
                            GOSUB Function_Draw_Effect
                        ENDIF
                    ENDIF
                    REMOVE_TEXTURE_DICTIONARY
                ENDIF
                PrevArmor = NextArmor
            ENDIF
            //--
            IF TEST_CHEAT "DGINI"
                GOSUB LoadIniFile
                PRINT_HELP_STRING "Danger Color: Reloaded!"
            ENDIF
        ENDIF
    GOTO Danger_Sprite
    TERMINATE_THIS_CUSTOM_SCRIPT

    Function_Draw_Effect:
        USE_TEXT_COMMANDS 1
        AlfaColor = 0
        WHILE (AlfaColor < iniAlfaMax)   // in
        AND (AlfaColor < 255)
            WAIT 0
            DRAW_SPRITE 1 320.0 240.0 650.0 480.0 255 255 255 AlfaColor
            AlfaColor += effectLevel
        ENDWHILE
        WHILE (AlfaColor > iniAlfaMin)   // out
        AND (AlfaColor > 0)
            WAIT 0
            DRAW_SPRITE 1 320.0 240.0 650.0 480.0 255 255 255 AlfaColor
            AlfaColor -= effectLevel
        ENDWHILE        
        USE_TEXT_COMMANDS 0
    RETURN

    LoadIniFile:
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "On" temp
            temp = 1
            WRITE_INT_TO_INI_FILE temp "cleo\Danger Effect ( Um Geek ).ini" "Settings" "On"
        ELSE
            SWITCH (temp)
                CASE -1
                    TERMINATE_THIS_CUSTOM_SCRIPT
                    BREAK
                CASE 0
                    WHILE NOT TEST_CHEAT "DNCON"
                        WAIT 0
                    ENDWHILE
                    PRINT_HELP_STRING "Danger Color: ON!"
                    BREAK
            ENDSWITCH
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Effect_Level"  effectLevel
            effectLevel = 5
            WRITE_INT_TO_INI_FILE effectLevel "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Effect_Level"
        ELSE
            IF (effectLevel > 50)
                effectLevel = 50
                WRITE_INT_TO_INI_FILE effectLevel "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Effect_Level"
            ENDIF
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Max"  iniAlfaMax
            iniAlfaMax = 255
            WRITE_INT_TO_INI_FILE iniAlfaMax "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Max"
        ELSE
            IF (iniAlfaMax < 0)
                iniAlfaMax = 0
            ENDIF
            IF (iniAlfaMax > 255)
                iniAlfaMax = 255
            ENDIF
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Min" iniAlfaMin
            iniAlfaMin = 25
            WRITE_INT_TO_INI_FILE iniAlfaMin "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Alfa_Min"
        ELSE
            IF (iniAlfaMin < 0)
                iniAlfaMin = 0
            ENDIF
            IF (iniAlfaMin > 255)
                iniAlfaMin = 255
            ENDIF
        ENDIF
        IF NOT READ_INT_FROM_INI_FILE "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Show_life_reset" iniShowGain
            iniShowGain = 0
            WRITE_INT_TO_INI_FILE iniShowGain "cleo\Danger Effect ( Um Geek ).ini" "Settings" "Show_life_reset"  
        ENDIF      
    RETURN
}
SCRIPT_END


Última edição por Um Geek em Sab 12 Ago 2017, 20:28, editado 2 vez(es) (Razão : Correções importantes)
avatar
Mensagens Nível 1
Mensagens Nível 1
Mensagens : 22
Reputação : 1
Desde : 06/11/2015
Idade : 14
Localização : Florianópolis - Santa Catarina
Ver perfil do usuário

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Qua 09 Ago 2017, 15:46
Se não me engano vi um desses no MixMods
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Título : Carinha que mora logo ali
Mensagens : 386
Reputação : 94
Desde : 07/03/2017
Localização : BH - MG
Link : http://emcodigo.blogspot.com.br/
Ver perfil do usuáriohttp://asvezesanime.blogspot.com.br/

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Qua 09 Ago 2017, 17:16
Deve de ter, eu só vi mesmo no God of War, tem também o som do coração batendo mais rápido conforme a vida diminuir, mas é separado.

______________________________
Estou organizando meu google drive que esta uma bagunça cleo misturado com lua, versões misturadas e etc então qualquer problema em links antigos é por causa disto então me avise caso tenha interesse no link
avatar
Mensagens Nível 3
Mensagens Nível 3
Mensagens : 182
Reputação : 3
Desde : 02/06/2017
Localização : Vila Velha, Estado do Espírito Santo
Link : 127.0.0.1:80
Ver perfil do usuário

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Qui 10 Ago 2017, 21:36
@Um Geek escreveu:[...] Se já existe este mod eu não sei, mas certas coisas prefiro fazer que ir procurar já que parece fáceis. [...]

É disso que eu falo. Mais pessoas deveriam pensar assim. Haveriam mais opções invés de usar uma única versão dum certo mod bugado.

Eu encontrei dois SFXs de aceleração cardíaca. Pode ser que te ajude (provavelmente numa futura versão? Com mais uma ideia original inovadora?).
https://onedrive.live.com/?id=root&cid=0C1851AB2D6976F3
avatar
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Não quero acreditar, quero saber.
Mensagens : 21880
Reputação : 666
Desde : 03/05/2012
Idade : 21
Localização : Ibitinga - SP
Link : www.MixMods.com.br
Ver perfil do usuáriohttp://MixMods.com.br

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Sex 11 Ago 2017, 00:49
Você usou textura com resolução sem ser potência de 2, e ainda colocou mip-mapping sem compressão (o que aparentemente não funciona), e, mip-mapping em texturas de interface?? Ainda sendo esse tipo de textura, faz sentido algum colocar mip-mapping.

Você não baixou o Magic.TXD da MixMods? Eu tentei deixar um aviso com tutorial bem chamativo lá em cima do botão de download, mas ninguém lê e faz os mods tudo errado.

edit: fui testar o mod e o efeito está errado, ele tá tipo assim:

______________________________

Mestre3224 voltou, ainda há esperanças no Youtube.
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Título : Carinha que mora logo ali
Mensagens : 386
Reputação : 94
Desde : 07/03/2017
Localização : BH - MG
Link : http://emcodigo.blogspot.com.br/
Ver perfil do usuáriohttp://asvezesanime.blogspot.com.br/

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Sab 12 Ago 2017, 12:05
Nunca vi um tutorial sobre textura, eu baixei o magic txd no GTAGarage.com. Não dei atenção a isto de mipmap (HMM)
Configurações de tempo do efeito, intensidade do alfa são configurados no arquivo ini.
_____________________
Editado

Eu não tinha visto problema no corte do efeito, quando a cor chegava no máximo voltava a zero, a solução não foi difícil.
code:

Código:

    Function_Draw_Effect:
        USE_TEXT_COMMANDS 1
        Counter = 0
        WHILE (Counter <= effectSpeed)
            Counter ++
            IF (recuo = 0)
                IF (AlfaColor < iniAlfaMax)
                    AlfaColor += iniAlfa
                ELSE
                    recuo = 1
                ENDIF
            ELSE
                IF (AlfaColor > 0)
                    AlfaColor -= iniAlfa
                ELSE
                    recuo = 0
                ENDIF
            ENDIF
            DRAW_SPRITE 1 320.0 220.5 672.0 477.0 255 255 255 AlfaColor
            WAIT 0
        ENDWHILE
        USE_TEXT_COMMANDS 0
    RETURN


Só coloquei uma variável para fazer o retorno do fade.

Sobre a medida da tela, pode ser que não fique mesmo múltiplo de 2, eu uso uma ferramenta que criei para fazer isto, ela copiar coordenadas do mapa, coordenadas da tela e faz as medidas.  (HMM)

imagem:

@Veryzon escreveu:
Eu encontrei dois SFXs de aceleração cardíaca. Pode ser que te ajude (provavelmente numa futura versão? Com mais uma ideia original inovadora?).
https://onedrive.live.com/?id=root&cid=0C1851AB2D6976F3

Valeu pelos efeitos. Já tenho isto aqui, como outros mods que tenho costumo deixar em off já que não é algo extraordinário.
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Mensagens : 1923
Reputação : 20
Desde : 30/05/2013
Localização : Estância Velha - RS
Ver perfil do usuário

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Sab 12 Ago 2017, 12:40
Saber que deve usar resolução com potência de 2, compressão etc, é o que qualquer pessoa deve saber para criar mod. Não sabe nem o que é mip-map... Lê isso, por que vejo que tu não usa nem o Widescreen Fix.

Se eu não estou com o Silent's Patch, Widescreen Fix, Mix Sets etc, os mods essenciais para jogar, posso ter o GTA instalado que eu não vou abri-lo.
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Título : Carinha que mora logo ali
Mensagens : 386
Reputação : 94
Desde : 07/03/2017
Localização : BH - MG
Link : http://emcodigo.blogspot.com.br/
Ver perfil do usuáriohttp://asvezesanime.blogspot.com.br/

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Sab 12 Ago 2017, 12:52


Saber que deve usar resolução com potência de 2, compressão etc, é o que qualquer pessoa deve saber para criar mod. Não sabe nem o que é mip-map... Lê isso, por que vejo que tu não usa nem o Widescreen Fix.

No meu GTA além do Mixsets eu só uso isto



Nem acelerador para o jogo iniciar rápido ou outros fix e etc, apesar de ter baixado todos e mais alguns.

Procuro afastar o mínimo possível do de como o GTA vem. E quem disse que não sabe o que é mip-map? Só não dei importância a isto, não sou mod Corporation, só faço para mim mesmo e compartilho alguns. Não sei porque mas sinto uma hostilidade pokerface
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Mensagens : 1923
Reputação : 20
Desde : 30/05/2013
Localização : Estância Velha - RS
Ver perfil do usuário

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Sab 12 Ago 2017, 13:21
Hostilidade? (tu não conheceu o Djjr de antigamente kk)
É que isso são coisas básicas que qualquer modder deve saber, e se você ainda não sabe, lê o tutorial que o Djjr postou na Mix. Não estou sendo hostil nem nada...
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Título : Carinha que mora logo ali
Mensagens : 386
Reputação : 94
Desde : 07/03/2017
Localização : BH - MG
Link : http://emcodigo.blogspot.com.br/
Ver perfil do usuáriohttp://asvezesanime.blogspot.com.br/

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Sab 12 Ago 2017, 13:38
Vou ver o tutorial de textura, até porque até pouco tempo atrás eu usava o txdworkshop. Eu li a bastante tempo este tutorial de como montar um bom GTA ai, eu nem sabia o que era mod ainda, quando saiu o mixset tirei muita coisa que antes usava que ele substitui como memory fix e etc. quanto o fastloader por exemplo eu sempre curti a abertura do jogo, cortar ela para mim seria um crime -q  Resumindo tudo eu só comecei a fazer algo para gta nesta data que eu me registrei ai do lado, antes eu só devo ter adaptado alguns veículos para steering e ImVehFt  então não sei muita coisa mesmo, seria uma façanha eu conseguir isto tão rápido (D)


Anexo:

imagem:

De quase 2mb para menos de 500kb, vou aproveitar e fazer umas melhorias. reparei que por padrão o magic txd coloca mipmap sem compressão nas texturas sec
avatar
Scripter CLEO - Intermediário
Scripter CLEO - Intermediário
Título : Carinha que mora logo ali
Mensagens : 386
Reputação : 94
Desde : 07/03/2017
Localização : BH - MG
Link : http://emcodigo.blogspot.com.br/
Ver perfil do usuáriohttp://asvezesanime.blogspot.com.br/

Re: Efeito de cor na tela ao receber dano ( corrigido )

em Seg 14 Ago 2017, 15:00
@Kevin Prestes escreveu:
por que vejo que tu não usa nem o Widescreen Fix.

Dei uma olhada neste fix ai, não é algo que eu precise porque uso o gta em janela, ai só redimensionar ela que fica correto, também aquele fix do aero é outro que não me faria falta pois curto o tema clássico do windows

imagem:



Até curto assim que vejo como fica as coisas nos diferentes tipos de tela.  (BG)
Conteúdo patrocinado

Re: Efeito de cor na tela ao receber dano ( corrigido )

Permissão deste fórum:
Você não pode responder aos tópicos neste fórum