LINK/2012
LINK/2012
Programador - Avançado
Programador - Avançado
Mensagens : 7655
Reputação : 349
Desde : 03/05/2012
Sab 30 Jun 2012, 16:38
O que todos estavam esperando, criar alguma coisa!
Massssss, vamos com calma né?

Para criar atores nos temos algumas etapas:
  1. Solicitar o modelo do ator.
  2. Aguardar o modelo estar disponivel.
  3. Criar o ator.
  4. Marcar o modelo como não mais necessario.


1. Solicitando o modelo
(Essa lição vai servir não apenas para atores, então entenda)

GTA é um jogo grande e por incrivel que pareça é mais leve do que muito joguinho por ai...
Por ser um jogo grande os modelos não podem ficar na memoria (da GPU) o tempo todo, precisa haver uma harmonia de quando o modelo é necessario e quando não é!

Para criar qualquer modelo no jogo você precisa solicita-lo, ou seja, pedir ele, para isso usamos o opcode:
Código:
0247: load_model #ADMIRAL
(Trocando o #ADMIRAL por qualquer outro modelo)

Para ver uma lista de modelos no sanny builder digite # e vai aparecer uma lista... Esses nomes vão ser substituido por numeros (o ID do modelo) ao ser compilado, então se você ver que não tem um modelo lá, você pode usar o ID do modelo no lugar.

Essas duas sentenças são equivalentes
Código:
0247: load_model #BMYRI
0247: load_model 20
Porque o BMYRI é o modelo ID 20.

Ao contrario do que muitos pensam, o opcode 0247 não carrega o modelo de uma vez, o que esse opcode faz é:
Modelo ja esta carregado? Aumenta o contador de referencias
Caso contrario Carregue-o


Contador de referencias? É, a cada requisição de um mesmo modelo um contador de referencias é aumentado para dizer quantas coisas no jogo estão utilizando o modelo.


2. Verificando a disponibilidade do modelo
(Essa lição vai servir não apenas para atores, então entenda)

Certo, você solicitou o modelo, agora você precisa verificar se ele esta disponivel, e so continuar se ele estiver disponivel.
Para verificar a disponibilidade do modelo se usa o opcode:
Código:
0248:  model #BMYRI available

Se o modelo ja estiver carregado quando solicitamos ele, essa condição vai retornar verdadeiro de primeiro, se não devemos esperar ele ficar disponivel, ou seja, vamos fazer um loop que faça esperar ate o modelo estar disponivel:
Código:
repeat
    wait 0
until 0248:  model #BMYRI available

Pronto, agora o codigo so vai continuar a criação quando o modelo estiver finalmente disponivel para uso!

3. A criação do ator

Tudo certo, solicitamos o modelo e esperamos ele ficar disponivel, agora vamos criar o ator!!
Para isso iremos usar o opcode:
Código:
009A: 2@ = create_actor_pedtype 4 model #BMYRI at 0.0 0.0 0.0
(ATENÇÃO: O modelo MALE01 esta SEMPRE disponivel!)

Nos enviamos 5 parametros e iremos receber um valor.
Esse valor que vamos receber é a HANDLE do nosso ator, é uma referencia a um objeto do jogo (Objeto é tudo desde atores a predios a texturas...), sempre que um opcode pedir um ator como parametro devemos enviar a handle desse ator.
Temos uma handle em uma variavel global, que devemos usar para referenciar o CJ como ator:
Código:
$PLAYER_ACTOR ou $3
(mesma coisa, se lembra? numeros)

Voltando ao opcode de criação do ator, o primeiro parametro (4), é o tipo de pedestre, para uma lista dos tipos de pedestres clique aqui . (Existe tambem uma lista de pedtypes no Help do Sanny Builder, mas eu prefiro a do link que passei, é muito mais detalhada)

O segundo parametro é o modelo que queremos criar, dispensa explicações certo?
O terceiro, quarto e quinto parametro são as coordenadas XYZ do modelo, lembra do ultimo tutorial?
O sexto e ultimo (retorno) eu ja expliquei, a handle do ator.

Certo, queremos criar o ator ao lado do CJ, como fazer isso? A Opcodes Search Tool do Sanny Builder é nossa amiga, lembre-se sempre dela!
Código:
00A0: store_actor $PLAYER_ACTOR position_to $TEMPVAR_FLOAT_1 $TEMPVAR_FLOAT_2 $TEMPVAR_FLOAT_3
04C4: store_coords_to $TEMPVAR_FLOAT_1 $TEMPVAR_FLOAT_2 $TEMPVAR_FLOAT_3 from_actor 215@ with_offset 1.0 3.0 1.0
(Existem opcodes similares para atores, carros e objetos, basta procurar na search tool ok?)

A diferença entre esses dois é que um pega a coordenada exata do CJ e o outro pega a coordenada do CJ somada pelas coordenadas XYZ especificadas la no fim.
Vamos usar a segunda, que soma as coordenadas, afinal queremos o ator ao lado do CJ e não no mesmo lugar dele, dois corpos não ocupam o mesmo lugar no espaço!! (Ok, No GTA essa regra não é aplicavel (D) )


Código:
04C4: store_coords_to 10@ 11@ 12@ from_actor $PLAYER_ACTOR with_offset 3.0 0.0 0.0
Ja entendeu né, pegamos a coordenada do CJ com uma diferença de X 3.0, o retorno foi nas variaveis 10@ 11@ e 12@ !

Então vamos criar o ator nessa posição que achamos:
Código:
009A: 0@ = create_actor_pedtype 4 model #BMYRI at 10@ 11@ 12@

Perfeito, mas ainda não terminamos o processo!

4. Marcar o modelo como não mais necessario
Pronto, ja usamos o modelo para o que precisavamos, criar o ator, agora vamos marcar ele como não mais necessario, porque... não precisamos mais dele!

Usamos o opcode:
Código:
0249: release_model #BMYRI

O que esse opcode faz é diminuir o contador de referencias e se esse contador chegar a zero o jogo vai remover o modelo da memoria (GPU).

Se não fizermos isso o contador de referencias vai ficar mal pois aumentamos o contador por um e nunca diminuimos ele e assim o modelo nunca vai sair da memoria!

5.1 Marcar o ator como não mais necessario

Quando não precisarmos mais do ator, devemos marcar ele como não mais necessario, sendo assim o jogo toma controle do ator e quando ele ficar distante ele pode ser destruido.

Código:
01C2: remove_references_to_actor 0@ // Like turning an actor into a random pedestrian

5.2 Destruir o ator!
Uma alternativa a simplismente dizer que o jogo pode tomar controle do ator é mandar ele pro inferno, destruir ele na hora!
Código:
009B: destroy_actor 0@ // Destroi o ator na hora
034F: destroy_actor_with_fade 0@ // Destroi o ator com um efeito de fade out


6. Mais opcodes de atores?!
Certo, você quer mais opcodes de atores né? Podemos discutir sobre eles depois, mas você ja pode começar a tentar usa-los, joga na search tool a palavra "actor" (A SEARCH TOOL MEU AMIGO, SEMPRE!) e você vai ver uma lista com varios opcodes relacionados a atores.

7. Script de exemplo
Terminamos a lição, aqui esta um script de exemplo pra vocês.

Spoiler:
Código:
{
Comandos:
    Use "ACTOR" para criar o ator (Atenção, não marcamos o ator como não mais necessario aqui)

    Veja o efeito de cada um dos jeitos de tirar o controle do ator da script!:
        Use "MARK" para marcar o ator como não mais necessario
        Use "DESTROY" para destruir o ator sem fade
        Use "FADE" para destruir o ator com fade
}

{$CLEO}

// Algumas constantes para ajudar o entendimento da script
const     
    MyActor        = 0@            // A handle do ator

    IsActorCreated  = 1@            // Flag que diz se o ator ta criado, para impedir de criarmos dois na mesma variavel
                                    // Porque dai perderiamos a handle de um deles.
                                   
    ActorModel      = #BMYRI        // Trocar o model da script, basta trocar a constante :)
   
end

IsActorCreated = FALSE
while true
    wait 500
   
    if 0ADC:  test_cheat "ACTOR"
    then
        if IsActorCreated == true      // Não criar outro ator enquanto o nosso ator tiver criador !
        then
            0ACA: show_text_box "Remove o controle do ator antes de criar outro!"
            continue
        end
   
        0247: load_model ActorModel    // Solicitamos o modelo
       
        repeat      // Vamos aguardar o modelo ficar disponivel...
            wait 0
        until 0248:  model ActorModel available
       
        // Agora vamos criar o ator ao lado do CJ     
        04C4: store_coords_to 10@ 11@ 12@ from_actor $PLAYER_ACTOR with_offset 3.0 0.0 0.0
        009A: MyActor = create_actor_pedtype 4 model ActorModel at 10@ 11@ 12@
       
        wait 0  // Vamos esperar o ator ser criado, ok?
        0249: release_model ActorModel  // Ja criamos o ator, então não precisamos mais do seu modelo...

        0ACA: show_text_box "Ator criado"       
        IsActorCreated = TRUE  // Temos uma handle na 0@, não quero sobreescrever a handle deste!
        continue
    end
   
    if 0ADC:  test_cheat "MARK"
    then
        01C2: remove_references_to_actor MyActor   
        0ACA: show_text_box "Ator sobre controle do jogo agora!"
        IsActorCreated = FALSE  // Podemos criar outro!
        continue
    end   

    if 0ADC:  test_cheat "DESTROY"
    then
        009B: destroy_actor MyActor
        0ACA: show_text_box "Ator destruido"
        IsActorCreated = FALSE
        continue
    end       

    if 0ADC:  test_cheat "FADE"
    then
        034F: destroy_actor_with_fade MyActor
        0ACA: show_text_box "Ator destruido, com fade out"
        IsActorCreated = FALSE
        continue
    end
   
end



Última edição por LINK/2012 em Sab 30 Jun 2012, 17:19, editado 1 vez(es)
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Sab 30 Jun 2012, 17:03
me aposentei, agr nao toh mais convertendo os tutoriais do LINK/2012, agr ele tah fazendo novos e jah direto no forum Fuch That Guy

vei, legal este script ai no fim, eh uma boa ideia pra testes e talz
✖ŦĦƗΔǤØ✖
✖ŦĦƗΔǤØ✖
Mensagens Nível 1
Mensagens Nível 1
Mensagens : 19
Reputação : 0
Desde : 03/06/2012
http://babiloniahack.blogspot.com.br/
Sab 30 Jun 2012, 18:27
Eu gosto de baralhos que andam :)


Última edição por LINK/2012 em Sab 30 Jun 2012, 18:31, editado 1 vez(es) (Razão : flooder)
LINK/2012
LINK/2012
Programador - Avançado
Programador - Avançado
Mensagens : 7655
Reputação : 349
Desde : 03/05/2012
Sab 30 Jun 2012, 18:30
Você ta maluco meu irmão? ta querendo floodar vai floodar na casa do caralho,
aqui no meu topico se não flooda não desgraça
EduardoJ.
EduardoJ.
Mensagens Nível 5
Mensagens Nível 5
Mensagens : 607
Reputação : 34
Desde : 04/05/2012
Idade : 24
Localização : Anápolis - Goias
Sab 30 Jun 2012, 19:47
Tutorial muito bom, to entendendo tudo, coisas q eu usava pq vi tutos errados kkkkkkk

______________________________
"Sabe o que é princesa, hoje eu encontrei a pessoa que eu procuro. Uma pessoa que eu quisesse comigo vinte e cinco horas por dia. Uma pessoa que me entendesse que eu pudesse confiar. E essa pessoa princesa. Essa pessoa. Sou eu!" - Blitz
[EMOJI DE RISOS] kk



"Não importa quanto a vida possa ser ruim, sempre existe algo que você pode fazer, e triunfar. Enquanto há vida, há esperança. " - Stephen Hawking.
Murai The Killer
Murai The Killer
Mensagens Nível 4
Mensagens Nível 4
Mensagens : 260
Reputação : 0
Desde : 03/06/2012
Idade : 32
Localização : Santa Terezinha de Itaipu, Paraná
Link : downseinfo.blogspot.com.br
http://downseinfo.blogspot.com.br
Dom 01 Jul 2012, 03:50
Bem explicativo, achei um pouco complicado mas consegui entender perfeitamente! Agora é só partir pro abraço e fazer meu GTA de rato de laboratório (quando me sobrar tempo é claro). Mais uma vez, parabéns!

______________________________
Quem abre a mente, reduz o mundo. (Neoqjav)
Fabio
Fabio
Programador - Avançado
Programador - Avançado
Mensagens : 18271
Reputação : 388
Desde : 04/05/2012
Idade : 24
Link : gtamodvicio.blogspot.com
http://gtamodvicio.blogspot.com
Dom 01 Jul 2012, 14:40
@LINK/2012 escreveu:
GTA é um jogo grande e por incrivel que pareça é mais leve do que muito joguinho por ai...

Mais leve que Minecraft Fuch That Guy

______________________________
10. Criação de atores 226c0ef57f9d7520d171cbadc68b3c56
Modifico quase qualquer coisa.   :)
------------------>>>http://gtamodvicio.blogspot.com/ <<<------------------
10. Criação de atores 76561198069372249
Meu PC:
Spoiler:

Configurações PC:
*Processador: Intel Core i7 4790K 4.00GHz LGA1150
*Placa Mãe: GIGABYTE GA-H97M-D3H Intel (LGA1150)
*HD: 1TB Seagate Barracuda 64MB Sata III 7200RPM (2x - RAID 0)
*HD²: SAMSUNG M3 Externo USB 5400RPM 1TB
*Placa de vídeo: Nvidia GTX660 2GB DDR5 192bit EVGA
*RAM: 8GB DDR3 1600MHZ Kingston HYPER X BEAST (2x4GB)
*Fonte: Corsair 600W Reais CX600M Modular - CP-9020060-WW (80 Plus Bronze)
*Gabinete: Gabinete Raidmax Super Hurricane Branco - 248WB
*Monitor: LG 23MP55HQ Full HD HDMI 23'
DamascenoFilho
DamascenoFilho
Mensagens Nível 1
Mensagens Nível 1
Mensagens : 5
Reputação : 0
Desde : 10/02/2014
Idade : 25
Localização : Fortaleza Ce
Seg 10 Fev 2014, 22:36
Como faço pra colocar um ator add ao jogo por aquele tuto do Junior? Tipo de add um ped ao jogo... Aí como sei o id dele no SB? ou é 265 que nem tá no ped.ide?
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Seg 10 Fev 2014, 22:50
tem q usar o ID msm, normal do .ide @_@

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
ismael-x2
ismael-x2
Mensagens Nível 1
Mensagens Nível 1
Mensagens : 1
Reputação : 0
Desde : 19/07/2014
Idade : 25
Localização : rs
Link : http://furiosusemtutos.blogspot.com/
Dom 20 Jul 2014, 13:51
VOU TER QU LER UM MONTE DE VEZ "JUNIOR JJR" E "LINK/2012" TIPO EU TENHO MUITA PRESA EU SOU APRESADO PARA APRENDER,MÁS SE EU ME APRESAR NÃO IREI APRENDER CERTO :(??

EU QUERO MUITO APRENDER A FAZER MOD CLEO,MÁS AINDA NÃO SEI E TENTO APRENDER,POIS NINGUÉM NASCE SABENDO...

VCS APRENDERÃO ASSIM DUMA HORA PRA OUTRA OU FOI DIFÍCIL DEMORADO? SERA QUE TENHO CHANCES DE APRENDER COM MAIS FACILIDADE E MAIS RÁPIDO?? AS VEZES PERCO AS ESPERANÇAS,MÁS SEMPRE ACREDITO EM MIM E DOU O MEU MELHOR.... EU NÃO GOSTAVA DE ESTUDAR,AGORA COMECEI A IR AS AULAS POR CAUSA DA SCRIPT...VONTADE DE APRENDER NÃO ME FALTA VEIS...MÁS SEI LÁ,,,, EU QUERIA MUITO QUE VCS COLOCASSEM UM TUTORIAL DE COMO CRIAR UM MOD SIMPLES MAIS A FRENTE "POR FAVOR" VLW PELA ATENÇAÃO D VCS MANOS, ABRAÇOS....  okay 
avatar
Convidado
Convidado
Dom 20 Jul 2014, 14:19
melhor do que esse é? Só se te derem o script pronto e dizer "Isso aqui faz uma bola, foda-se como se cria a bola, como se posiciona a bola e de onde vem a bola, mas ele cria uma bola"
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Dom 20 Jul 2014, 19:56
Imsael, pode ir embora q aqui a gente ensina as pessoas, a gente quer ensinar as pessoas a fazer mods cleos e nao dar tudo na mao delas, A GENTE ENSINA, se vc nao quer aprender vai embora desse forum e nunca mais volte, se vc quer aprender, vai lah no primeiro tutorial, feche as portas do seu quarto, feche o facebook, desligue musicas, e passe quase 1 hora na frente do pc lendo e tentando entender cada linha de cada tutorial lendo e relendo cada uma delas, até chegar nesse com tudo oq tinha atras entendido... ou vc nao aprende

demorei 3 anos pra aprender tudo oq sei hoje, e nunca vi pessoas aprendendo cleo em 1 ou 2 meses e jah sabendo fazer coisas sem ter problemas... e quando uma pessoa tem facilidade e aprende tipo em 1 mes, eh pq a pessoa jah tinha conhecimento sobre programação...
eu demorei mais de meio ano pra aprender fazer coisas basicas e boas sem problemas e ajuda... isso pq eu nao tinha um tutorial desses como do LINK/2012, se vc tem um tutorial desses e ter forças pra aprender, consegue aprender em poucos meses

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 10:48
@Link
estou com uma dúvida, como faço para spawnar um ator em frente ao CJ?
obs: como se fosse um carro, o player digita um cheat e o ator aparece
JNRois12
JNRois12
Programador - Básico
Programador - Básico
Mensagens : 6341
Reputação : 65
Desde : 09/07/2012
Idade : 22
Localização : Potim - SP
Link : g1.globo.com/jornal-nacional/
Sex 25 Jul 2014, 11:06
Você só precisa pegar as coordenadas do player (0054 eu acho), e depois colocar um pequeno offset, aí é só spawnar o ator @_@
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 11:12
@JN
vou esperar o Link responder.
lembra da merda que ocorreu da ultima vez que tentei usar offset?
se tiver um opcode parecido com este abaixo:
Código:
  0ADD: spawn_car_with_model #COPCARLA at_player_location
mas para atores, eu agradeço, pois ele já pega o offset e tudo sem nada mais no código
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Sex 25 Jul 2014, 14:19
facil pra porra .-.
Código:
// carregar o modelo
#BMFORI.Load
038B: load_requested_models

// pegar coordenada na frente do CJ e criar o ator naquela coordenada
04C4: store_coords_to 1@ 2@ 3@ from_actor $player_actor with_offset 0.0 3.0 0.0 // uns 3 metros a frente do CJ
009A: 0@ = create_actor_pedtype 4 model #BMFORI at 1@ 2@ 3@

// marcar modelo como nao mais usado
#BMFORI.Destroy

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 14:30
@Valdir
obrigado
eu ainda sou noob demais em SCM/CLEO
o ator apareceu direitinho, vou tentar fazer a parte que eu planejei do mod sozinho.
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 15:37
@Valdir
consegui fazer o que eu queria
o script funciona assim: o jogador digita "RIVAL"(sem aspas), um lutador surge e ataca o CJ, o jogador luta com o rival por 2 minutos, o tempo de um Round de MMA, e não dá crash se o CJ mata o lutador, pois se o lutador morrer o CJ ganha e sai vivo do combate
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Sex 25 Jul 2014, 15:38
@_@

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 15:50
já está pronto, posso postar?
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Sex 25 Jul 2014, 15:54
postar aqui?
manda o source do script entao, dae aproveita pra eu apontar os erros e vc corrigir entao, dae aprende mais

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 15:57
ok
lá vai o código
Código:
{$CLEO}
0000:
while true
wait 0
if
0ADC:  test_cheat "RIVAL"
then
#VBMYBOX.Load
038B: load_requested_models
04C4: store_coords_to 1@ 2@ 3@ from_actor $player_actor with_offset 0.0 3.0 0.0
009A: 0@ = create_actor_pedtype 4 model #VBMYBOX at 1@ 2@ 3@
07A5: AS_actor 0@ attack_actor $PLAYER_ACTOR time 120000
0350: set_actor 0@ maintain_position_when_attacked 1
end
end






ao meu ver funciona, dá até pra usar armas(o que não é bom em lutas) que não dá crash.
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Sex 25 Jul 2014, 16:05
......resumindo, vc soh adicionou comando de ativação e setou ele para atacar o CJ, eu achei q vc tinha feito mais coisa, mas blz...

recomendo vc ler o tutorial q criei sobre Identação aqui:
https://brmodstudio.forumeiros.com/t4008-55-espaco-tabelado

deixar o script organizado e melhor pra ler:
Código:
{$CLEO}
0000:
while true
    wait 0
    if
    0ADC:  test_cheat "RIVAL"
    then
        #VBMYBOX.Load
        038B: load_requested_models
        04C4: store_coords_to 1@ 2@ 3@ from_actor $player_actor with_offset 0.0 3.0 0.0
        009A: 0@ = create_actor_pedtype 4 model #VBMYBOX at 1@ 2@ 3@
        07A5: AS_actor 0@ attack_actor $PLAYER_ACTOR time 120000
        0350: set_actor 0@ maintain_position_when_attacked 1
    end
end

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
paulinho2108
paulinho2108
Veterano
Veterano
Mensagens : 1368
Reputação : 15
Desde : 22/04/2013
Idade : 27
Localização : uruguaiana/RS
Sex 25 Jul 2014, 16:08
@Valdir
eu só esqueci de identar , pois na faculdade eu aprendi isso.
mas no ponto funcional, está bom?
Junior_Djjr
Junior_Djjr
Scripter CLEO - Avançado
Scripter CLEO - Avançado
Título : Censurando since 2011
Mensagens : 22701
Reputação : 727
Desde : 03/05/2012
Idade : 25
Localização : Ibitinga - SP
Link : www.MixMods.com.br
http://MixMods.com.br
Sex 25 Jul 2014, 16:28
sim...

______________________________
BMS agora em nova plataforma:
Forum.MixMods.com.br
Conteúdo patrocinado
Permissão deste fórum:
Você não pode responder aos tópicos neste fórum